// TMW2 script
// Author: Jesusalva <admin@tmw2.org>
//
// Magic Script: TMW2_TRANSMIGRATION
//
// Attempts to make stuff from other stuff
// This is actually referred as transmutation in human-readable forms, and
// transmigration in scripts.

// Variables:
//   @transmemo: array of item1, amount1, ...
//               first element must be the main result item
//               (for display purposes).

-	script	sk#mkpot	32767,{
    end;
OnCall:
    // Check cooldown
    if (@mkpot_at > gettimetick(2)) {
        dispbottom l("Skill is in cooldown for @@.", FuzzyTime(@mkpot_at));
        end;
    }

    // Check requisites
    if (!MagicCheck(TMW2_TRANSMIGRATION, 215, -5))
        end;

    .@q=getq(General_Auldsbel);

    do {
        mes ".:: " + l("Transmutation Skill") + " ::.";
        mesc l("What will you transmute today?");
        mes "";
        menuint
            rif(@transmemo, l("Repeat %s", getitemname(@transmemo[0]))), 1,
            l("Crazy Rum"), CrazyRum,
            l("Coal"), 9901, // 9901 cheat code
            l("Mouboo Figurine"), MoubooFigurine,
            rif(.@q >= 9, l("Downgrade Snake Skin")), SnakeSkin,
            rif(.@q >= 9, l("Downgrade Snake Egg")), SnakeEgg,
            rif(.@q >= 9, l("Downgrade Snake Tongue")), SnakeTongue,
            rif(.@q >= 7, l("Downgrade Scorpion Stinger")), ScorpionStinger,
            rif(.@q >= 7, l("Downgrade Scorpion Claw")), ScorpionClaw,
            l("Downgrade Ore"), IronOre,
            l("Cancel"), 0;

        // Possible submenu.
        switch (@menuret) {
        case SnakeSkin:
            menuint
                l("Black Mamba Skin -> Mountain Snake Skin"), MountainSnakeSkin,
                l("Mountain Snake Skin -> Snake Skin"), SnakeSkin,
                l("Snake Skin -> Cave Snake Skin"), CaveSnakeSkin,
                l("Cancel"), 0;
            break;
        case SnakeEgg:
            menuint
                l("Black Mamba Egg -> Mountain Snake Egg"), MountainSnakeEgg,
                l("Mountain Snake Egg -> Snake Egg"), SnakeEgg,
                l("Snake Egg -> Cave Snake Egg"), CaveSnakeEgg,
                l("Cancel"), 0;
            break;
        case SnakeTongue:
            menuint
                l("Black Mamba Tongue -> Mountain Snake Tongue"), MountainSnakeTongue,
                l("Mountain Snake Tongue -> Snake Tongue"), SnakeTongue,
                l("Snake Tongue -> Cave Snake Tongue"), CaveSnakeTongue,
                l("5x Snake Tongues -> Tortuga Tongue"), TortugaTongue,
                l("Cancel"), 0;
            break;
        case ScorpionStinger:
            menuint
                l("Black Scorpion Stinger -> Red Scorpion Stinger"), RedScorpionStinger,
                l("Red Scorpion Stinger -> Scorpion Stinger"), ScorpionStinger,
                l("Cancel"), 0;
            break;
        case ScorpionClaw:
            menuint
                l("Golden Scorpion Claw -> Black Scorpion Claw"), BlackScorpionClaw,
                l("Black Scorpion Claw -> Red Scorpion Claw"), RedScorpionClaw,
                l("Red Scorpion Claw -> Scorpion Claw"), ScorpionClaw,
                l("Cancel"), 0;
            break;
        case IronOre:
            menuint
                l("Platinum Ore -> Iridium Ore"), IridiumOre,
                l("Iridium Ore -> Titanium Ore"), TitaniumOre,
                l("Titanium Ore -> Lead Ore"), LeadOre,
                l("Lead Ore -> Tin Ore"), TinOre,
                l("Tin Ore -> Gold Ore"), GoldOre,
                l("Gold Ore -> Silver Ore"), SilverOre,
                l("Silver Ore -> Copper Ore"), CopperOre,
                l("Copper Ore -> Iron Ore"), IronOre,
                l("Iron Ore -> Coal"), Coal,
                l("Cancel"), 0;
            break;
        default:
            break; // @menuret is final.
        }


        // Set requirements.
        switch (@menuret) {
        case 1:// Skip display, just repeat.
            break;
        case CrazyRum:
            setarray @transmemo, CrazyRum, 2, Plushroom, -18, Milk, -5;
            break;
        case 9901: // This is coal
            setarray @transmemo, Coal, 2, WoodenLog, -6;
            break;
        case MoubooFigurine:
            setarray @transmemo, MoubooFigurine, 1, WoodenLog, -1;
            break;

        case MountainSnakeSkin:
            setarray @transmemo, MountainSnakeSkin, 2, BlackMambaSkin, -1;
            break;
        case SnakeSkin:
            setarray @transmemo, SnakeSkin, 2, MountainSnakeSkin, -1;
            break;
        case CaveSnakeSkin:
            setarray @transmemo, CaveSnakeSkin, 2, SnakeSkin, -1;
            break;

        // Snake Egg Chain
        case MountainSnakeEgg:
            setarray @transmemo, MountainSnakeEgg, 2, BlackMambaEgg, -1;
            break;
        case SnakeEgg:
            setarray @transmemo, SnakeEgg, 2, MountainSnakeEgg, -1;
            break;
        case CaveSnakeEgg:
            setarray @transmemo, CaveSnakeEgg, 2, SnakeEgg, -1;
            break;

        // Snake Tongue Chain
        case MountainSnakeTongue:
            setarray @transmemo, MountainSnakeTongue, 2, BlackMambaTongue, -1;
            break;
        case SnakeTongue:
            setarray @transmemo, SnakeTongue, 2, MountainSnakeTongue, -1;
            break;
        case CaveSnakeTongue:
            setarray @transmemo, CaveSnakeTongue, 2, SnakeTongue, -1;
            break;
        case TortugaTongue:
            setarray @transmemo, TortugaTongue, 2, SnakeTongue, -5;
            break;

        // Scorpion Claw Chain
        case BlackScorpionClaw:
            setarray @transmemo, BlackScorpionClaw, 2, GoldenScorpionClaw, -1;
            break;
        case RedScorpionClaw:
            setarray @transmemo, RedScorpionClaw, 2, BlackScorpionClaw, -1;
            break;
        case ScorpionClaw:
            setarray @transmemo, ScorpionClaw, 2, RedScorpionClaw, -1;
            break;

        // Scorpion Stinger Chain
        case RedScorpionStinger:
            setarray @transmemo, RedScorpionStinger, 2, BlackScorpionStinger, -1;
            break;
        case ScorpionStinger:
            setarray @transmemo, ScorpionStinger, 2, RedScorpionStinger, -1;
            break;

        // Ore Chain (the biggest one)
        case IridiumOre:
            setarray @transmemo, IridiumOre, 2, PlatinumOre, -1;
            break;
        case TitaniumOre:
            setarray @transmemo, TitaniumOre, 2, IridiumOre, -1;
            break;
        case LeadOre:
            setarray @transmemo, LeadOre, 2, TitaniumOre, -1;
            break;
        case TinOre:
            setarray @transmemo, TinOre, 2, LeadOre, -1;
            break;
        case GoldOre:
            setarray @transmemo, GoldOre, 2, TinOre, -1;
            break;
        case SilverOre:
            setarray @transmemo, SilverOre, 2, GoldOre, -1;
            break;
        case CopperOre:
            setarray @transmemo, CopperOre, 2, SilverOre, -1;
            break;
        case IronOre:
            setarray @transmemo, IronOre, 2, CopperOre, -1;
            break;
        case Coal:
            setarray @transmemo, Coal, 2, IronOre, -1;
            break;
        default:
            Exception("ERROR, INVALID TRANSMIGRATION OPTION", RB_DEFAULT|RB_SPEECH); @menuret=0; break;
        }

        transDisplayReqArray(@transmemo);

        // Confirmation
        if (@menuret) {
            next;
            mesc l("Transmute?!");
            .@me=@menuret;
            if (askyesno() == ASK_NO)
                @menuret=0;
            else
                @menuret=.@me;
        }
    } while (!@menuret);

    // Close the dialog
    closeclientdialog;

    // Check and Consume the reagents
    // Failing to make crazy rum had this side effect:
    // percentheal 0, -2; // Additionally takes 2% of your MP


    // Do the roll from 1 to 100
    // Base success chance is 0%
    // Each abizit() point gives you 18% success rate (max 90%)
    // Each skill level gives you 1% success rate (max 10%)
    .@r=rand2(1, 100)-abizit()*18-getskilllv(TMW2_TRANSMIGRATION);

    // Backfire chance: 30%
    if (.@r >= 70) {
        dispbottom l("The spell backfires!");
        percentheal -(rand2(5, 15)), 0;
    // Chance for nothing to happen
    } else if (.@r >= 30) {
        dispbottom l("Your reagents vanish into emptiness!");
    // Chance for you getting a junk item
    } else if (.@r > 0) {
        dispbottom l("Your spell takes a mind of its own and shapes in something else!");
        getitem any(WarpedLog, .@me), 1;
    // You were successful
    } else if (transCheckArray(@transmemo)) {
        dispbottom l("*plim*");
    } else {
        dispbottom l("Not enough items!");
    }

    // set cooldown
    @mkpot_at=gettimetick(2);
    @mkpot_at=@mkpot_at+6;

    // Get a few mana experience points (this is NOT used by Mana Stone)
    GetManaExp(TMW2_TRANSMIGRATION, rand2(4,9));
    end;

OnInit:
    bindatcmd "sk-trans", "sk#mkpot::OnCall", 0, 100, 0;
    end;
}