// TMW2 scripts.
// Author:
//    Jesusalva
// Description:
//   Optional Dungeon Configuration File

026-8	mapflag	zone	SuperMMO

// Main Configuration and Warp NPC
026-6,86,78,0	script	#OPTDungeon	NPC_HIDDEN,0,0,{
    end;

OnTouch:
OnTouchNPC:
    if (!MK_WINNER) dispbottom l("The Alliance Expeditionary Force won't allow me beyond this point.");
    else warp "026-8", 93, 100;
    end;

OnBossDown:
    if (!playerattached()) end;
    getitem EvilWarpCrystal, 1;
    OPTBossCount += 1;
    switch (OPTBossCount) {
    case 1:
        getitem IntelligenceFruit, 1; break;
    case 2:
        getitem VitalityFruit, 1; break;
    case 3:
        getitem DexterityFruit, 1; break;
    case 4:
        getitem StrengthFruit, 1; break;
    case 5:
        getitem LuckFruit, 1; break;
    case 6:
        getitem AgilityFruit, 1; break;
    case 7:
        getitem GoldenBossGift, 1; break;
    case 8:
        getitem MercBoxEE, 1; break;
    case 9:
        getitem PrismGift, 1; break;
    case 10:
        getitem SaviorBlueprint, 1; break;
    default:
        // After this, you heal fully and gain extra EXP
        percentheal 100, 0;
        getexp OPTBossCount*200, OPTBossCount*10;
        // You can still get some low value, repeatable prizes in cycles of 40
        // However, this code does NOT start at zero!
        if      (OPTBossCount % 40 == 20)
            getitem Arcanum, 1;
        else if (OPTBossCount % 40 == 30)
            getitem TreasureKey, 1;
        else if (OPTBossCount % 40 == 0)
            getitem ArcmageBoxset, 1;
        else if (OPTBossCount % 40 == 10)
            getitem StrangeCoin, 5;
        break;
    }
    fix_mobkill(TopUnderling);
    end;
}