// TMW-2 Script
// Author:
//  Jesusalva
//  Pookie
// Description:
//  This NPC serves no purpose currently. She is here to make Tulimshar more crowded.
//  Now a believer to announce Halinarzo and Alvasus Quest.
// TODO: During rainy days, she could ask for an Umbrella

003-1,53,128,0	script	Aahna	NPC_ELVEN_FEMALE,{
    mesn;
    // Comment on the current weather
    .@mk = getmapmask("003-1");
    if (.@mk & MASK_RAIN)
        mesq l("Ugh, can you believe it is raining?! What thrash weather for a desert town!");
    else if (.@mk & MASK_SANDSTORM)
        mesq l("This sandstorm is horrible on my skin... I hope someday, someone invents a lotion for that.");
    else
        mesq l("Hello, What a lovely day for a stroll.");
    // Inform about the Sunday-only quest.
    next;
    mesn;
    mesq l("I heard every Sunday there's a party at Halinarzo Church, but to get there you need to pass through the Desert Canyon.");
    next;
    mesn;
    mesq l("I hope one day, they decide build a church here. It's a pain to travel there every time...");
    close;

OnInit:
    .sex = G_FEMALE;
    .distance = 5;
    end;

// Server Happy Hour
// Used to be Sunday 18:00~20:00
// Then it is Sunday 16:00~20:00
// Currently it is the whole weekend
OnSat0000:
    if (debug) end;
    $@EXP_EVENT=($GAME_STORYLINE >= 5 ? 15 : 10);
    $@EXP_EVENT_TIME=48;
    donpcevent "@exprate::OnPlayerCall";
    end;

OnSun0000:
    disablenpc .name$;
    end;

OnMon0000:
    enablenpc .name$;
    end;
}