// TMW-2 Script.
// Editor: Jesusalva
//
// Evol scripts.
// Authors:
//    Ablu
//    Qwerty Dragon
// Description:
//    Introduction NPC

002-1,49,36,0	script	LeftDoorCheck	NPC_HIDDEN,0,0,{
    if (!#TUTORIAL_DONE)
        #TUTORIAL_DONE = true;
    .@q = getq(ShipQuests_Arpan);
    if (.@q == 5) doevent instance_npcname("Magic Arpan")+"::OnTalk";

    close;
}

002-1,54,36,0	script	RightDoorCheck	NPC_HIDDEN,0,0,{
    if (!#TUTORIAL_DONE)
        #TUTORIAL_DONE = true;
    .@q = getq(ShipQuests_Arpan);
    if (.@q == 5) doevent instance_npcname("Magic Arpan")+"::OnTalk";

    close;
}


002-1,49,33,0	script	Magic Arpan	NPC_MAGIC_ARPAN,{
    showavatar NPC_MAGIC_ARPAN;

    .@q = getq(ShipQuests_Arpan);
    .@s = getq2(ShipQuests_Arpan);
    .@n = getq(General_Narrator);
    .@q_julia = getq(ShipQuests_Julia);

OnTalk:
    showavatar NPC_MAGIC_ARPAN;
    mesn;

    if (.@q > 5) goto L_Menu;
    setq ShipQuests_Arpan, 6;
    deltimer("Magic Arpan::OnSlow");

    mesq lg("Yeye, are you finally ready to go?");
    if (!TUTORIAL)
        mesc l("Protip: You skipped the tutorial. A lot of tutorial related dialog and quests will be skipped. You can change this anytime in %s > Game Settings.", b("@ucp"));
    next;

    select
        l("Yes, I want to find out who I am."),
        l("No, but what option do I have? I'm being railroaded!");
    mes "";

    if (@menu == 2) {
        mesn;
        mesq l("Ye not paying for your food and ye isn't a sailor like us! Ye should be standing on your own two feet.");
        next;
        mesn strcharinfo(0);
        mesq l("Thanks for your honesty, I guess.");
        next;
    }

    mes "";
    mesn;
    mesq l("Anyway, you should be thanking Juliet, she's the one who patched you up.");
    next;
    mesn;
    if (.@q_julia == 0)
        setq ShipQuests_Julia, 1;
    mesq lg("Yaya, you should go see her! She'll be happy to help you again.");
    next;
    mesc b(l(".:: Main Quest 1-1 ::.")), 3;
    msObjective(false, l("Talk to @@", l("Juliet")));
    tutmes l("Juliet is east (right) of %s.", .name$), l("Protip"), false;
    next;
    // Friendly reminder to new players
    if (StatusPoint == 48 && BaseLevel < 2) {
        mesc l("Remember to assign status points before fighting. By default, it can be done with %s.", b("F2")), 1;
    }
    goto L_Menu;


L_Menu:
    mesq l("What-yeye could I do for you today?");
    next;

    menu
        rif(.@q_julia < 2, lg("Where can I find Juliet?")), L_Julia,
        rif(!.@n, l("Can you tell me where I am?")), L_Where,
        rif(!.@n, l("Who are you?")), L_Who,
        rif(!.@n, l("I need a tutorial, where can I find help?")), L_Trainer,
        rif(!getq(ShipQuests_ArpanMoney), l("Do you know what happened to the gold I had on me when I was rescued?")), L_WhereMoney,
        l("Nothing, sorry."), -;

    closedialog;
    close;

L_Trainer:
    mes "";
    mesn;
    mesq l("There is an NPC called Trainer, just outside the ship.");
    next;
    mesn;
    mesq l("Just use the arrow key--, err, I mean, just walk to the door on the right. It's the one not guarded by Peter.");
    next;
    mesn;
    mesq lg("Make sure you're dressed and then speak with the captain. He'll give you a mission and unlock the ship's main door.");
    next;
    mesn;
    mesq l("All you need to do is walk outside, enter the biggest house, and speak with the Trainer. He'll teach you everything you need to know.");
    next;
    goto L_Menu;

L_Where:
    mes "";
    mesn;
    mesq lg("You're aboard our ship. We made port to a little island and we're actually yeye-ending our long merchant travelling adventure at the city of Tulimshar.");
    next;
    mesq l("We will be yeye-ing there in a few days, so we'll part ways there.");
    next;
    mesq l("You will notice the citizens are polite and they might help you find a job or help you figure out what happened to you out at sea.");
    next;

    goto L_Menu;

L_Julia:
    mes "";
    mesn;
    mesq lg("Just go right, yeye can't miss her. She's the only girl in this crew, oh well, except for you now yeyeye!", "Just go right, yeye  can't miss her. She's the only girl in this crew.");
    next;

    mesn "Narrator";
    mesc l("Use the arrow keys to walk over to the right and meet Juliet.");
    next;

    goto L_Menu;

L_Who:
    mes "";
    mesn;
    mesq l("Sorry! Allow me to introduce myself. My name is Arpan, but the other sailors call me Magic Arpan because I know one or two ya-ing magic tricks.");
    next;
    mesn;
    mesq l("They're not magic, but yayaya, people like to say it is! Yeyeye!");
    next;

    goto L_Menu;

L_WhereMoney:
    mes "";
    mesn;
    mesq l("Oh right, I almost forgot, here you go!");
    next;

    if (BaseLevel < 4) goto L_Apana;
    setq ShipQuests_ArpanMoney, 1;
    Zeny = Zeny + 35;
    message strcharinfo(0), l("You receive @@ GP!", 35);

    goto L_BeforeMenu;

L_Apana:
    mesn;
    mesq l("On second thought, come see me when you've gained a few levels. We can't have cheaters, ya know?");
    tutmes l("You need to have level %d or above.", 4);
    next;
    goto L_Menu;

L_BeforeMenu:
    mesn;
    goto L_Menu;

OnSlow:
    npctalk3 l("@@, do you need help? Are you lost? Click me!", strcharinfo(0));
    /*
    setcamnpc;
    showavatar NPC_MAGIC_ARPAN;
    mesn;
    mesq l("Yayaya, @@ is surely slow. Don't you remember how to walk? You can use arrow keys for that!", strcharinfo(0));
    next;
    mesn;
    mesc l("Here, speak to me, Magic Arpan! I'll help you get dressed."), 1;
    */
    addtimer(90000,"Magic Arpan::OnSlow");
    close;

OnInit:
    .sex = G_MALE;
    .distance = 6;
    end;
}