// TMW2 script
// Author: Jesusalva <admin@tmw2.org>
//
// Magic Script: TMW2_KALSPIKE
//
// Summons mouboo

-	script	sk#kalspike	32767,{
    end;

OnCall:
    // Other requeriments: 1x MushroomSpores
    if (countitem(MushroomSpores) < 1) {
        dispbottom l("You need 1x @@ to cast this skill.", getitemlink(MushroomSpores));
        end;
    }

    // Check cooldown
    if (@kalspike_at > gettimetick(2)) {
        dispbottom l("Skill is in cooldown for @@.", FuzzyTime(@kalspike_at));
        end;
    }

    // Setup
    @sk=TMW2_KALSPIKE;
    @mp=25;
    @amp=5;

    // Check if you have mana to cast
    // MagicCheck(SkillID, Mana{, MP per level})
    if (!MagicCheck(@sk, @mp, @amp))
        end;

    // Destroy reagents
    delitem MushroomSpores, 1;

    // set cooldown
    @kalspike_at=gettimetick(2);
    @kalspike_at=@kalspike_at+44;

    // As usual, magic profeciency affects success ratio
    if (rand(1,6) < abizit()+1) {
        .@mobId=PoisonSpikyMushroom;
        // Summon Magic
        // SummonMagic(SkillID, MobID{, SkillLevelPerMob=2{, Level Override}})
        SummonMagic(@sk, .@mobId, 4, MAGIC_LVL+getskilllv(@sk)-1);
    } else {
        dispbottom l("The spell fails!");
    }

    // Get 4~5 mana experience point (this is NOT used by Mana Stone)
    GetManaExp(@sk, rand(4,5));

    end;

OnInit:
    bindatcmd "sk-kalspike", "sk#kalspike::OnCall", 0, 100, 0;
    end;
}