// TMW2 script
// Author: Jesusalva <admin@tmw2.org>
//
// Magic Script: TMW2_FAIRYKINGDOM
//
// Summons snakes (mountain snakes if GHQ was completed and enough skill)

-	script	sk#fairykingdom	32767,{
    end;

OnCall:
    // Other requeriments: 1x Fluo Powder
    if (countitem(FluoPowder) < 1) {
        dispbottom l("You need 1x @@ to cast this skill.", getitemlink(FluoPowder));
        end;
    }

    // Check cooldown
    if (@fairykingdom_at > gettimetick(2)) {
        dispbottom l("Skill is in cooldown for @@.", FuzzyTime(@fairykingdom_at));
        end;
    }

    // Setup
    @sk=TMW2_FAIRYKINGDOM;
    @mp=400;
    @amp=42;

    // Check if you have mana to cast
    // MagicCheck(SkillID, Mana{, MP per level})
    if (!MagicCheck(@sk, @mp, @amp))
        end;

    // Destroy reagents
    delitem FluoPowder, 1;

    // set cooldown
    @fairykingdom_at=gettimetick(2);
    @fairykingdom_at=@fairykingdom_at+47-abizit();

    // As usual, magic profeciency affects success ratio
    if (rand(1,6) < abizit()+1) {
        .@mobId=any(FireFairy, EarthFairy, WaterFairy, WindFairy, PoisonFairy);
        // Summon Magic
        // SummonMagic(SkillID, MobID{, SkillLevelPerMob=2{, Level Override}})
        SummonMagic(@sk, .@mobId, 4, MAGIC_LVL+getskilllv(@sk)-1);
    } else {
        dispbottom l("The spell fails!");
    }

    // Get 3~4 mana experience point (this is NOT used by Mana Stone)
    GetManaExp(@sk, rand(3,4));

    end;

OnInit:
    bindatcmd "sk-fairykingdom", "sk#fairykingdom::OnCall", 0, 100, 0;
    end;
}