// TMW2 Script
// Author:
//  Jesusalva
// Description:
//  Forgetful

027-1,131,100,0	script	Ezra	NPC_BLACKWIZARD,{
    mesn l("Ezra, the very Forgetful");
    mesq l("What was I doing before...? I forgot!");
    next;
    mesc l("Teaching Ezra your skills will make you both forget them."), 1;
    mesc l("Once your skill is forgotten, the Magic Skill Points used will be freed."), 1;
    mesc l("But be careful: Only 2MSP-costed skills can be forgotten, and learning fees WON'T be given back!"), 1;
    do
    {
        next;
        mesc l("Which skill will you FORGET permanently today?"), 1;
        menuint
            l("Uhm... Bye?"), 0,
            rif(getskilllv(MG_NAPALMBEAT),          l("Napalm Beat")), MG_NAPALMBEAT,
	    	rif(getskilllv(MG_FROSTDIVER),          l("Frost Diver")), MG_FROSTDIVER,
	    	rif(getskilllv(SO_FIREWALK), 			l("Fire Walk")), SO_FIREWALK,
	    	rif(getskilllv(KN_AUTOCOUNTER),			l("Counter Attack")), KN_AUTOCOUNTER,
	    	rif(getskilllv(ASC_METEORASSAULT),		l("Ground Strike")), ASC_METEORASSAULT,
	    	rif(getskilllv(EVOL_AREA_PROVOKE),		l("Area Provoke")), EVOL_AREA_PROVOKE,
	    	rif(getskilllv(EVOL_MASS_PROVOKE),		l("Mass Provoke")), EVOL_MASS_PROVOKE,
	    	rif(getskilllv(AB_HIGHNESSHEAL),		l("High Healing")), AB_HIGHNESSHEAL,
	    	rif(getskilllv(GC_DARKILLUSION),		l("Sudden Attack")), GC_DARKILLUSION,
	    	rif(getskilllv(NV_TRICKDEAD),			l("Trick Dead")), NV_TRICKDEAD,
            l("None at the moment!"), 0;
        if (!@menuret)
            goto L_Close;
        mes "";
        mesc l("Skill @@ will be permanently lost!", @menuret), 1;
        mesc l("Continue anyway?"), 1;
        if (askyesno() == ASK_YES) {
            .@lv=getskilllv(@menuret)+1;
            skill @menuret, 0, 0;
            MAGIC_PTS-=.@lv;
            mesc l("Skill @@ has been lost", @menuret), 3;
            mesc l("You recovered @@ magic skill points", .@lv), 3;
        } else {
            mesn l("Ezra, the very Forgetful");
            mesq l("Uh, what?");
        }
    } while (@menuret);
    next;

L_Close:
    mesn l("Ezra, the Very Forgetful");
    mesq l("Do you know where my brother Enzo is? I forgot that too!");
    close;

OnInit:
    .sex = G_MALE;
    .distance = 5;
    end;

}