// TMW-2 Script.
// Author:
//    Jesusalva
// Notes:
//    Phoenix Rebirth

025-2,108,23,0	script	Phoenix Rebirth	NPC_BRGUARD_SPEAR,{
    setpcblock(255, true);
    mesn;
    mesq l("Hello there. My name is %s.", .name$);
    next;
    mesn;
    switch (REBIRTH) {
    case 0:
        mesc l("Once you reach level 99, I'll offer you a life-time opportunity to delete all your levels and experience for your first rebirth!");
        .@blvl=99;
        break;
    case 4:
        mesc l("Once you reach level 150, I'll offer you a life-time opportunity to delete all your levels and experience for your first rebirth!");
        .@blvl=150;
        break;
    default:
        mesc l("Unfortunately you cannot rebirth anymore!");
        close;
        break;
    }
    next;
    mesn;
    mesq l("Rebirth is free. Here are the perks you'll get by doing the rebirth:");
    mes "";
    mes l("* +3 Inventory Slots")+" ##1##BWIP##b##0";
    mes l("* +2 in all attributes, permanently");
    mes l("* +1 Magic Skill Point");
    mes l("* +5%% EXP Gain and Drop Chance, permanently");
    mes l("* 1 %s", getitemlink(SupremeGift));
    if (BaseLevel < .@blvl) {
        setpcblock(255, false);
        close;
    }
    next;
    mesn;
    mesq l("Are you interested? You'll keep %s your equipment, magic, quest progression, craft recipes, money, whatever else which is not a level. Not even Job level won't be reset!", b(l("ALL")));
    mesc l("This cannot be undo later!"), 1;
    next;
    setpcblock(255, false);
    inventoryplace NPCEyes, 7;
    select
        l("Do not rebirth"),
        l("Rebirth"),
        l("Do not rebirth");
    mes "";
    if (@menu != 2)
        close;
    mesc l("ARE YOU SURE? THIS CANNOT BE UNDONE LATER!!"), 1;
    if (askyesno() != ASK_YES)
        close;

    // Okay, then a rebirth it is!
    expandinventory(3);
    REBIRTH+=1;
    STATUSUP_STR+=2;
    STATUSUP_AGI+=2;
    STATUSUP_VIT+=2;
    STATUSUP_INT+=2;
    STATUSUP_DEX+=2;
    STATUSUP_LUK+=2;
    resetlvl(3);
    StatusResetReinvest();
    NewcomerEXPDROPUP();
    getitembound SupremeGift, 1, 4;
    warp "005-1", 40, 117;
    LOCATION$="Candor";
    close;
}