// TMW2/LoF scripts.
// Authors:
//    TMW-LoF Team
//    Jesusalva
// Description:
//    Sell pets (LoFQuest_Pets) (mesn Ace Ventura)

017-1,192,23,0	script	Pet Detective	NPC_PET_TAMER,{
    .@q=getq(LoFQuest_Pets);
    if (.@q) goto L_Menu;
    mesn;
    mesq l("I investigate missing pets. Many flee from their owners because they die pathetically or forgot to feed them.");
    next;
    mesn;
    mesq l("If they at least read the @@, they wouldn't have such problems.", getitemlink(PetcaringGuide));
    mesq l("The Pet Caring Guild will collect them after a while, and capture many others.");
    next;
    mesn;
    mesq l("So, what do you say about a deal? I'll affiliate you on the Pet Caring Guild for only 350.000 GP!");
    if (Zeny < 350000)
        close;
    next;
    if (askyesno() == ASK_NO)
        close;
    mes "";
    if (Zeny < 350000) {
        mesn;
        mesq l("Oh, but we are affiliated with Jesusalva, whom hates cheaters. So, meet your dismissal!");
        percentheal -100, 0;
    }
    Zeny=Zeny-350000;
    getexp 0, 500;
    setq LoFQuest_Pets, 1;
    setarray PETMEMO, 0, 0, 0;
    mesn;
    mesq l("Congrats! You are now part from the Pet Caring Guild. You can now buy pets! %%G");
    close;

L_Menu:
    if (!.stock)
        goto L_OutOfStock;
    mesn;
    mesq l("I currently have some pets with me. For most, you need to finish their Grand Hunter Quest, of course.");
    mes "";
    select
        rif(GHMEMO[GHQ_GetQuestIDByMonsterID(Maggot)] >= 10000, l("Cute Maggot")),
        rif(GHMEMO[GHQ_GetQuestIDByMonsterID(ForestMushroom)] >= 10000, l("Forest Mushroom")),
        l("Nothing at the moment.");

    mes "";
    switch (@menu) {
        case 1:
            if (PDQ_InnerSwitch(Maggot, MaggotSlime, 40))
                .stock-=1;
            break;
        case 2:
            if (PDQ_InnerSwitch(ForestMushroom, MushroomSpores, 30))
                .stock-=1;
            break;
        default:
            closedialog;
            goodbye;
            close;
    }

    next;
    goto L_Menu;

L_OutOfStock:
    mesn;
    mesq l("Sorry, I don't have any pets at the moment.");
    close;

OnInit:
    .sex=G_MALE;
    .distance=5;
    .stock=1;
    end;

OnSun0000:
OnWed1200:
    .stock+=1;
    end;
}