// TMW2 Script
// Author: 
//  Crazyfefe
//  Jesusalva
// Description:
//  Dark Invocator Quest
// Notes:
//      You'll be tempted to sell the Dark Desert Mushroom for 8'000 GP. There's a but.
//      You won't be able to finish this quest. Ok, no biggie, it was not that rewarding.
//      But you won't be able to do more Everburn Powder. And it can be required on another
//      quest. And there won't be other way to get the Powder. So DO NOT SELL IT. Think ahead.

007-1,152,155,0	script	Zarkor	NPC_MIRAJ,{
    .@q=getq(TulimsharQuest_DarkInvocator);
    if (BaseLevel <= 30)
        goto L_Weak;
    switch (.@q) {
        case 0:
            goto L_Start;
            break;
        case 1:
            mesn "Zarkor, the Dark Summoner";
            mesq l("Talk to Zitoni, the Alchemist of Candor. He may look humble, but he is the greatest alchemist of this world. I need five @@.", getitemlink(EverburnPowder));
            close;
            break;
        case 2:
            goto L_Price;
            break;
        case 3:
            mesn "Zarkor, the Dark Summoner";
            mesq l("Talk to Zitoni, and deliver the @@. I can't give you another one, they're super rare.", getitemlink(DarkDesertMushroom));
            close;
            break;
        case 4:
            goto L_Quest;
            break;
        case 5:
            mesn "Saulc, the Bug Master";
            mesq l("Sorry, the script is broken again. Blame the usual that the torches are nowhere to be found.");
            next;
            mesn "Saulc, the Bug Master";
            mesq l("Once that gets out of the way, this NPC will be finished. See you then!");
            close;
            break;

    }
    mesn;
    mesq l("One day... One day! ONE DAY I'LL GET REVENGE ON YOU, MONSTER KING!");
    close;

L_Weak:
    mesn;
    mesq lg("Stay out of harm way. Nothing to see here. Stay away, pathetically weak human.");
    close;

L_Start:
    mesn;
    mesq l("Hey... You... Come here.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("I am Zarkor, the Dark Summoner. I want to do a dark summoning ritual, but there are strings attached.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("I need to buy your silence. I'll reward you greatly when I'm done. But first, I need to know if you'll be loyal to me.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("To prove me your faith, bring me 1 @@ or 1 @@.",getitemlink(Ruby),getitemlink(Topaz));
    mesq l("Such precious gem, is not something you would give for free, unless you are interested on my... rituals.");
    next;
    mesn strcharinfo(0);
    select
        l("Indeed. Sorry. I'm not giving you anything."),
        rif(countitem(Ruby) >= 1, l("I swear silence, over this bloody ruby."),
        rif(countitem(Topaz) >= 1, l("I swear silence, over this shining topaz.");

    mes "";
    switch (@menu) {
        case 1:
            mesn;
            mesq l("Very well. This conversation never happened.");
            next;
            mesn;
            mesq l("But if you regret this choice later... You know where you can find me.");
            close;
            break;
        case 2:
            delitem Ruby, 1; // Acc: 667 GP
            setq TulimsharQuest_DarkInvocator, 1;
            break;
        case 3:
            delitem Topaz, 1; // Acc: 800 GP
            setq TulimsharQuest_DarkInvocator, 1;
            break;
    }
    mesn "Zarkor, the Dark Summoner";
    mesq l("Very well. I shall now share with you the details of this rite.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("I will summon the Monster King. Don't ask me my reasons. I know this will put Tulimshar in danger. But I will still do it.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("For that, I need to light five torches. The pentagram, the magic, and all the else are with me. Just light the torches.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("Talk to Zitoni, the Alchemist of Candor. He may look humble, but he is the greatest alchemist of this world. I need five @@.", getitemlink(EverburnPowder));
    close;

L_Price:
    mesn strcharinfo(0);
    mesq l("Zitoni refused to make the Powder.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("I thought he would. After all, Everburn Powder... is not a mere powder.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("Well, you gave me the gems, so I trust you. Here, take this @@.", getitemlink(DarkDesertMushroom));
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("Take much care with it. It is very, very rare drop from a rare monster from a difficult, high level area.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("Deliver it to Zitoni on my name. He'll trust it. The relation between me and Zitoni... goes way back.");
    getitem DarkDesertMushroom, 1;
    setq TulimsharQuest_DarkInvocator, 3;
    close;

L_Quest:
    if (countitem(EverburnPowder) < 5) {
        mesn "Zarkor, the Dark Summoner";
        mesq l("This is not enough, I need 5 @@ to perform the rite. Go talk with Zitoni.", getitemlink(EverburnPowder));
        close;
    }
    mesn "Zarkor, the Dark Summoner";
    mesq l("Good, good, you have enough powder. Now I need you to lit all five torches with them.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("Once you lit one of them, monsters will pour out, so take care to don't die.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("If you die, you'll have to begin again. And there is the experience penalty, too.");
    next;
    mesn "Zarkor, the Dark Summoner";
    mesq l("Good luck, because you'll need it. Talk to me once all of them are lit, and I'll SUMMON DAH MONSTER KING.");
    setq TulimsharQuest_DarkInvocator, 5;
    close;

L_Finish:
    // Yadda yadda yadda dialog

    // These values were taken from Experience table, and are magic numbers
    getexp 9174, 412;
    // Pay roughly what you spent
    //  Powder + Trips  + Gems + Sulf + Iron + Ash + Profit = Money
    // (3000*5 + 4*500G + 1000 + 5*84 + 5*66 + 5*80 + 850) = 20.000
    Zeny=Zeny+20000;

    close;


OnInit:
    .sex = G_MALE;
    .distance = 6;
    end;

}