// TMW2 scripts.
// Author:
//    Saulc
// Description:
//    Light Armor shop keeper.
// Variables:
//    CandorQuests_Rosen
// Values:
//    0    Default.
//    1    BlackSmith quest delivered.
//    2    Chelios Quest given.
//    3    Chelios Quest done.
//    4    BlackSmith gave the sword.
//    5    Light Armor Shop quest delivered.
//    6    Light Armor Shop gave the cloths.

005-4,29,36,0	script	Rosen	NPC_GUARD1,{

    function explain_ironingot {
        speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
            l("Did you see Jhedia the blacksmith in Tulimshar? He might know how you could get this."),
            l("Nevertheless, you can sap it on Bif, if you are lucky.");

        return;
    }

    function rosen_quest {
        speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
            l("I asked Calypsan to dye this tank top, now it has an unique look!");

        narrator S_LAST_NEXT, l("You pick up the package.");

        setq CandorQuests_Rosen, 6;

        return;
    }

    speech S_LAST_NEXT,
        l("Welcome to Tolchi and Rosen Shop."),
        l("What would you like today?");

    do
    {
        .@rosen = getq(CandorQuests_Rosen);
        select
            rif(.@rosen == 5, lg("I came to retrieve a package for Rosen.")),
            menuaction(l("Trade")),
            l("How can I get iron ingot?"),
            menuaction(l("Quit"));

        switch (@menu)
        {
            case 1: //broken need a fix
                rosen_quest;
                closedialog;
                goodbye;
                close;
            case 2:
                closedialog;
                shop "Shop";
                close;
            case 3:
                explain_ironingot;
                break;
            case 4:
                closedialog;
                goodbye;
                close;
        }
    } while (1);

OnTimer1000:
    domovestep;

OnInit:
    initpath "move", 28, 36,
             "dir", DOWN, 0,
             "wait", 31, 0,
             "move", 31, 36,
             "dir", DOWN, 0,
             "wait", 31, 0,
             "move", 25, 35,
             "dir", UP, 0,
             "wait", 2, 0,    
             "move", 29, 36,
             "dir", DOWN, 0,
             "wait", 31, 0;       
    initialmove;
    initnpctimer;
    .distance = 5;
}