// TMW2 scripts.
// Author:
//    Saulc
//    GonzoDark
// Variables:
//    0    CandorQuest_Maya
// Values:
//    00   Default, no quest selected.
//    01   First quest accepted: Need 3 cotton cloth and 3 maggot slime
//    02   First quest completed: Reward Candor shirt
//    03   wolvern tooth +20k + 2000monster point ->claw pendant

005-1,42,37,0	script	Maya	NPC_RAIJIN_FEMALE_LEGION_ARTIS,0,0,{
    .@maya = getq(CandorQuest_Maya);

    if (.@maya == 0)
        goto L_QuestNotStarted;
    if (.@maya == 1)
        goto L_QuestAccepted;
    if (.@maya == 2)
        goto L_NextQuestPending;

L_QuestNotStarted:
    mesn;
    mesq l("Hi there, I can always use a helping hand around here, are you the one for the job?");
    mes "";
    menu
        l("Sure"),L_Next,
        l("No, thanks."),L_Close;

L_Next:
    mes "";
    mesn;
    mesq l("Good! First, let us test if you are resourceful. Bring me 3 @@ and 3 @@. That should be enough!", getitemlink(CottonCloth), getitemlink(MaggotSlime));
    setq CandorQuest_Maya, 1;
    close;

L_QuestAccepted:
    mesn;
    mesq l("I see you have brought @@/3 @@ and @@/3 @@ for me",countitem("Cotton Cloth"),getitemlink(CottonCloth),countitem("Maggot Slime"),getitemlink(MaggotSlime));
    mes "";
    menu
        rif(countitem("Cotton Cloth") >= 3 && countitem("Maggot Slime") >= 3, l("Here they are!")), L_QuestCompleted,
        rif(countitem("Cotton Cloth") < 3 && countitem("Maggot Slime") < 3, l("Oh, then I don't have enough! I'll bring more later!")), L_Close,
        l("Can we get back to that later?"), -;
    close;

L_Close:
    close;

L_QuestCompleted:
    delitem CottonCloth, 3;
    delitem MaggotSlime, 3;
    set Zeny, Zeny + 300;
    getitem CandorShirt, 1;
    setq CandorQuest_Maya, 2;

    mes "";
    mesn;
    mesq l("Thanks for the help. Here, take this shirt and some money.");
    close;

L_NextQuestPending:
mesn;
mesq l("Thanks again for the help. You have proven that you are resourceful. Come back again later.");
close;


OnInit:
    .sex = G_FEMALE;
    .distance = 4;
    end;
}