// TMW2 Script
// Author:
//    TMW Org.
//    Jesusalva
// Description:
//    Part of Anwar Field quest

004-1,107,67,0	script	Anwar	NPC_RAIJIN,{
    .@q=getq(TulimsharQuest_AnwarField);
    if (BaseLevel < 15) goto L_Weak;
    /*
    if (.@q >= 15) goto L_Done;
    if (.@q >= 13) goto L_GiveEomie;
    if (.@q >= 11) goto L_GiveTinris;
    if (.@q == 10) goto L_GiftMaterial;
    */
    if (.@q >= 6) goto L_FirstTry;
    if (.@q == 5) goto L_TryIt;
    if (.@q >= 1) goto L_FirstTry;

    mesn;
    mesq l("Hi. Could you perhaps be interested in doing some small errand for me?");
    menu
        l("Sure!"),L_Sure,
        l("I'm busy, sorry."),L_Close;

L_Sure:
    mes "";
    mesn;
    mesq l("Great! Eomie, the girl on Tulimshar's magic academy, is an alchemist. She probably makes fertilizers.");
    next;
    mesn;
    mesq l("This farm is dying due constant monster attacks, and without them, Tulimshar might face a famine.");
    next;
    mesn;
    mesq l("Please, talk to her. Maybe she understands the direness of the situation and help... But you know. Elves.");
    setq TulimsharQuest_AnwarField, 1;
    close;

L_FirstTry:
    mesn;
    mesq l("Good luck getting the fertilizer from Eomie! Many elves simply refuse to cooperate until it affects them directly.");
    close;

L_TryIt:
    .@q2=getq2(TulimsharQuest_AnwarField);
    mesn;
    mesq l("You've brought me fertilizer! Let me see if it works...");
    next;
    setq2 TulimsharQuest_AnwarField, .@q2+1;

    // Fail chances are 100% - 10% per attempt
    if (rand(0,100) < 100-(.@q2*10)) {
        setq1 TulimsharQuest_AnwarField, 6;
        mes col("Nothing happens.", 9);
        next;
        mesn;
        mesq l("Uh... Something should happen, right? Can you get another one?");
    } else {
        setq1 TulimsharQuest_AnwarField, 7;
        mes col("Evil worms crawl from earth and starts devoring the plants!", 9);
        next;
        mesn;
        mesq l("Uh... That should not happen, right? RIGHT?");
        next;
        mesn;
        mesq l("Don't just stand here! Go fetch help, NOW!!");
    }

    close;

L_Weak:
    hello;
    end;

L_Close:
    close;

OnInit:
    .@npcId = getnpcid(0, .name$);
    //setunitdata(.@npcId, UDT_HEADTOP, 2929); // TODO: This NPC is an Elf and therefore, CANNOT use NPCEyes.
    setunitdata(.@npcId, UDT_HEADMIDDLE, ArtisTankTop);
    setunitdata(.@npcId, UDT_HEADBOTTOM, CottonTrousers);
    setunitdata(.@npcId, UDT_WEAPON, DeepBlackBoots); // Boots
    setunitdata(.@npcId, UDT_HAIRSTYLE, 6);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 14);

    .sex = G_MALE;
    .distance = 4;
    end;
}