// Author:
//    Saulc
//    Jesusalva

003-1,45,80,0	script	Well	NPC_NO_SPRITE,{
    .@COST_PER_BOTTLE = 50;

    mes l("This well have a mechanism to fill water bottles. It costs @@ gp per bottle.", .@COST_PER_BOTTLE);
    mes l("You need the bottle, too. Too bad, not even water is free in this world!");
    input .@count;

    if (.@count == 0)
        close;
    .@Cost = .@count * .@COST_PER_BOTTLE;
    .@empty = countitem("EmptyBottle");

    if (.@empty < .@count)
        goto L_NotEnoughBottles;
    if (Zeny < .@Cost)
        goto L_NotEnoughMoney;
    getinventorylist;
    if (@inventorylist_count == 100
        && countitem("BottleOfSweaWater") == 0
        && .@empty > .@count)
            goto L_NotEnoughSlots;

    set Zeny, Zeny - .@Cost;
    delitem "EmptyBottle", .@count;
    getitem "BottleOfSweaWater", .@count; // TODO FIXME: "Swea" water? Also, this is not sea water...
    close;

L_NotEnoughBottles:
    mes l("You don't have that many empty bottles!");
    close;

L_NotEnoughMoney:
    mes l("You don't have enough gp! You need @@ gp.", .@Cost);
    close;

L_NotEnoughSlots:
    mes l("You don't have room for these bottles!");
    close;

OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}