// TMW2 scripts.
// Authors:
//    Jesusalva
// Description:
//    Mouboo Renting (var MOUBOO_RENTTIME )

003-1,63,31,0	script	Taree	NPC_ELVEN_MAN_MOUBOO_SHOP,{
    if (MOUBOO_RENTTIME > gettimetick(2))
        goto L_Rented;

    mesn;
    mesq l("Moo!");
    next;
    mesn;
    mesq l("Do you want to rent a Mouboo? It allows quick traveling!");
    next;
    menuint
        rif(Zeny > 100, l("Rent 1 day for 100 GP")), 100,
        rif(Zeny > 270, l("Rent 3 days for 270 GP")), 270,
        rif(Zeny > 600, l("Rent 7 days for 600 GP")), 600,
        rif(Zeny > 1200, l("Rent 15 days for 1200 GP")), 1200,
        rif(Zeny > 2000, l("Rent 30 days for 2000 GP")), 2000,
        l("Don't rent a mouboo."), 0;
    mes "";
    switch (@menuret) {
        case 0:
            close;
        case 100:
            .@time=86400; break;
        case 270:
            .@time=259200; break;
        case 600:
            .@time=604800; break;
        case 1200:
            .@time=1296000; break;
        case 2000:
            .@time=2592000; break;
        default:
            Exception("Invalid price: "+@menuret, RB_DEFAULT|RB_SPEECH|RB_ISFATAL);
            break;
    }
    inventoryplace RidingMouboo, 1;
    MOUBOO_RENTTIME=gettimetick(2)+.@time;
    Zeny-=@menuret;
    rentitem RidingMouboo, .@time;
    close;

L_Rented:
    mesn;
    mesq l("Moo!");
    close;

OnInit:
    .distance=4;
    end;
}