// TMW2 scripts.
// Author:
//    Saulc
//    Jesusalva
// Inac Give a sharp knife for 20 Piou Feathers to player over level 12, // before Tycoon give it but only bafter level 18 that was too high !
003-1,55,82,0	script	Inac	NPC_PLAYER,{

    .@Inac = getq(TulimsharQuest_Inac);
    if (BaseLevel < 12) goto L_TooWeak;
    if (.@Inac == 1) goto L_Check;
    if (.@Inac == 2) goto L_Complete;

L_GiveTask:
    mesn;
    mesq lg("Hello, wanderer! Welcome in Tulimshar");
    next;
    mesq l("Is Nard who bring you here?");
    next;

    menu
        l("Yeah Nard's Sailors saved my life and bring me there!"), L_Quest,
        l("I need to go."), L_Quit;

L_Quest:
    mes "";
    mesn;
    mesq l("Tulimshar is surrounded by strong monster, if you go out with your poor equipment, you're going to be infamous, boy.");
    next;
    mesn;
    mesq l("I probably can give you a Sharp Knife! If you want to?");
    next;

    menu
        l("Really? It would be great!"), L_Start,
        l("Better do this some other time..."), L_Quit;


L_Start:
    setq TulimsharQuest_Inac, 1;
    mes "";
    mesn;
    mesq l("If you from Candor you probably have some fluffy's yellow feathers, i use them to make pillow:");
    goto L_List;

L_Quit:
    mes "";
    mesn;
    mesq l("Have a good day then..");
    close;

L_List:
    mes "";
    mesn;
    mes l("To get my knife bring me this::");
    mes l("@@/20 @@", countitem(PiouFeathers), getitemlink(PiouFeathers));
    close;

L_Check:
    mesn;
    mesq l("Did you brought me feathers?");
    next;
    menu
        l("Yes! Here you are"), L_Give,
        l("I forgot what you need!"), L_List,
        l("Later."), L_Quit;

L_Give:
    if (
        countitem(PiouFeathers)         < 20
        ) goto L_Lying;

    inventoryplace SharpKnife, 1;

    delitem(PiouFeathers, 20);

    getitem(SharpKnife, 1);
    getexp(200, 1);
    setq(TulimsharQuest_Inac, 2);

    mes "";
    mesn;
    mesq l("Enjoy this new weapon, Hope you're going to be successful.");
    close;

L_Complete:

    mesn;
    mesq l("Many stories are told about this city sewers.");
    next;
    mesn;
    mesq l("One of them is really crazy, though: They say that there is a legendary monster down there.");
    next;
    mesn;
    mesq l("That's just nonsense though, I've been there thousands of times and saw no such thing.");
    if (getq(TulimsharQuest_Sewers) > 0)
        close;
    next;
    mesn;
    mesq l("Anyway, there's a barrier to prevent monsters from attacking the city from below.");
    next;
    mesn;
    mesq l("To enter on them, you need to be level 25 and use the following chant: \"Blame Saulc\". I don't know why, but that open doors!");
    setq TulimsharQuest_Sewers, 1;
    close;

L_Lying:
    mesn;
    mesq l("No no no, that's wrong.");
    next;
    mesc l("I need more feathers for a fair deal.");
    next;

    goto L_List;

L_TooWeak:
    mesn;
    mesq l("Hello little kid, Watch Out there's maggot behind you %%a !");
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, Bandana);
    setunitdata(.@npcId, UDT_HEADMIDDLE, VneckJumper);
    setunitdata(.@npcId, UDT_HEADBOTTOM, CottonTrousers);
    setunitdata(.@npcId, UDT_WEAPON, LousyMoccasins); // Boots
    setunitdata(.@npcId, UDT_HAIRSTYLE, 7);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 17);

    .sex = G_MALE;
    .distance = 4;
    end;
}