//===== eAthena Script ========================================
//= Shuriken Blacksmith
//===== By: ==================================================
//= Au{R}oN
//===== Current Version: =====================================
//= 1.2a
//===== Compatible With: =====================================
//= eAthena 1.0+
//===== Description: =========================================
//= Shuriken Weapon Maker.
//===== Additional Comments: =================================
//= Converted from Aegis
//= 1.0 Added the 4 Shuriken. [Au{R}oN]
//= 1.1 Fix getitem bugs and add if ninja job check. [Au{R}oN]
//= 1.2 more bugs fixed,wrong labels, missing stuf, etc[Lupus]
//= 1.2a added missing next;
//============================================================

que_ng.gat,22,62,3	script	Taitsu	709,{

	mes "[Taitsu]";
	if(Class!=Job_Ninja){
		mes "Sorry, buy I can use my ability only for Ninja Class.";
		close;
	}
	mes "Hello";
	mes "I'm Taitsu, the Blacksmith of Fuuma Ninja.";
	next;
	mes "[Taitsu]";
	mes "Due to a burst of interest, my life became very miserable.";
	mes "So, I'm taking everything from the beginning, but haven't made weapon in a long time...";
	next;
	mes "[Taitsu]";
	mes "However, in terms of making Fuuma weapons, no one can make them any better then mine.";
	mes "Here, take a look.";
	next;
	menu "Fuuma Shuriken Beneki",M_BENEKI,"Fuuma Shuriken Daisharin",M_DAIS,
		"Fuuma Shuriken Daisharin [4]",M_DAIS4,"Fuuma Shuriken Rekka",M_REKKA;

//=====================BENEKI========================
M_BENEKI:
	mes "[Taitsu]";
	mes "You want make ^FF0000Fuuma Shuriken Beneki^000000";
	mes "Fuuma Shuriken Beneki needs:";
	mes "50 Steel, 20 Harpy's Feathers, 5 Oridecon, and 90.000z.";
	mes "Do you want me to make it?";
	next;
	menu "Yes",-,"No Thanks",M_NOPE;

	mes "[Taitsu]";
	mes "So let me check for your items...";
	set @z,90000;
	if(Zeny < @z) goto L_NOZENY;
	if(countitem(999)<50 || countitem(7115)<20 || countitem(984)<5) goto L_NOITEMS;
	set Zeny,Zeny-@z;
	delitem 999,50;
	delitem 7115,20;
	delitem 984,5;
	next;
	getitem 13300,1;
	mes "[Taitsu]";
	mes "Ok, enjoy with your new weapon.";
	close;

//=====================DAISHARIN========================
M_DAIS:
	mes "[Taitsu]";
	mes "You want make ^FF0000Fuuma Shuriken Daisharin^000000";
	mes "Fuuma Shuriken Daisharin needs:";
	mes "30 Steel, 100 Tassels, 2 Oridecon, and 40.000z.";
	mes "Do you want me to make it?";
	next;
	menu "Yes",-,"No Thanks",M_NOPE;

	mes "[Taitsu]";
	mes "So let me check for your items...";
	set @z,40000;
	if(Zeny < @z) goto L_NOZENY;
	if(countitem(999)<30 || countitem(7301)<100 || countitem(984)<2) goto L_NOITEMS;
	set Zeny,Zeny-@z;
	delitem 999,30;
	delitem 7301,100;
	delitem 984,2;
	next;
	getitem 13301,1;
	mes "[Taitsu]";
	mes "Ok, enjoy with your new weapon.";
	close;

//=====================DAISHARIN4========================
M_DAIS4:
	mes "[Taitsu]";
	mes "You want make ^FF0000Fuuma Shuriken Daisharin[4]^000000";
	mes "Fuuma Shuriken Daisharin[4] needs:";
	mes "20 Cracked Diamonds, 1 Fuuma Shuriken Daisharin, 2 Oridecon, and 40.000z.";
	mes "Do you want me to make it?";
	next;
	menu "Yes",-,"No Thanks",M_NOPE;

	mes "[Taitsu]";
	mes "So let me check for your items...";
	set @z,40000;
	if(Zeny < @z) goto L_NOZENY;
	if(countitem(733)<20 || countitem(13301)<1 || countitem(984)<3) goto L_NOITEMS;
	set Zeny,Zeny-@z;
	delitem 733,20;
	delitem 13301,1;
	delitem 984,3;
	next;
	getitem 13302,1;
	mes "[Taitsu]";
	mes "Ok, enjoy with your new weapon.";
	close;

//=====================REKKA========================
M_REKKA:
	mes "[Taitsu]";
	mes "You want make ^FF0000Fuuma Shuriken Rekka^000000";
	mes "Fuuma Shuriken Rekka needs:";
	mes "50 Steel, 100 Live Coal, 2 Oridecon, 50 Burning Stone and 78.000z.";
	mes "Do you want me to make it?";
	next;
	menu "Yes",-,"No Thanks",M_NOPE;

	mes "[Taitsu]";
	mes "So let me check for your items...";
	set @z,78000;
	if(Zeny < @z) goto L_NOZENY;
	if(countitem(733)<50 || countitem(7098)<100 || countitem(7097)<100 || countitem(7521)<50) goto L_NOITEMS;
	set Zeny,Zeny-@z;
	delitem 733,50;
	delitem 7098,100;
	delitem 7097,100;
	delitem 7521,50;
	next;
	getitem 13303,1;
	mes "[Taitsu]";
	mes "Ok, enjoy with your new weapon.";
	close;

//=====================I'M SORRY========================
L_NOITEMS:
	next;
	mes "[Taitsu]";
	mes "Sorry, but you not have all required items.";
	emotion e_sry;
	close;

L_NOZENY:
	next;
	mes "[Taitsu]";
	mes "I'm sorry, but you need "+@z+"z";
	emotion e_cash;
	close;

M_NOPE:
	mes "[Taitsu]";
	mes "Ok came back when you want.";
	close;
}