//=====Hercules Script =======================================
//= Armor Enchanter
//===== By: ==================================================
//= L0ne_W0lf
//===== Current Version: =====================================
//= 1.3a
//===== Description: =========================================
//= [Official Conversion]
//= Add a +1, +2, or +3 random stat to a specified armor.
//===== Additional Comments: =================================
//= 1.0 First version.
//= 1.1 Corrected typo (Sit -> Suit) (bugreport:4586)
//= 1.2 Optimized. [Euphy]
//= 1.3 Fixed some typos and optimized a little more. [Daegaladh]
//= 1.3a Added 'disable_items' command. [Euphy]
//============================================================

prontera,165,60,2	script	Apprentice Craftsman	1_F_MERCHANT_01,{
	disable_items;
	mes "[Apprentice Craftsman]";
	if (Zeny >= 400000) {
		mes "I've been studying ways to enhance an armor to maximize its capability.";
		next;
		mes "[Apprentice Craftsman]";
		mes "Enchanting is an awesome skill that infuses a mysterious status powers into the armor's hidden socket.";
		next;
		mes "[Apprentice Craftsman]";
		mes "However, you have to keep in mind that if there are two armors of the same kind in your possession, the Enchantment will be applied in the order they are placed in your inventory.";
		next;
		mes "[Apprentice Craftsman]";
		mes "In that case, the Enchantment may be applied to an item which you didn't mean to Enchant. So just bring ^5555ffONE Armor^000000 you want enchanted to be safe...";
		next;
		mes "[Apprentice Craftsman]";
		mes "I'm not responsible for what would happen if you have more than one of the same kind in your inventory.";
		next;
		switch(select("Non Slotted Armor.:Slotted Armor.:High Grade Armor.:Maybe next time.")) {
		case 1:
			setarray .@items[0],2307,2309,2314,2316,2321,2325,2327,2328,2330,2332,2334,2335,2341,2344,2346,2348,2350,2337,2386,2394,2395,2396;
			set .@j,50;
			break;
		case 2:
			setarray .@items[0],2311,2318,2319,2320,2308,2310,2315,2317,2322,2324,2326,2331,2333,2336,2342,2345,2347,2349,2351;
			set .@j,55;
			set .@k,1;
			break;
		case 3:
			setarray .@items[0],2364,2365,2391,2374,2375,2376,2377,2378,2379,2380,2381,2382,2387,2388,2389,2390;
			set .@j,60;
			break;
		case 4:
			mes "[Apprentice Craftsman]";
			mes "Please come back when you have any interest in enchanting your armor.";
			close;
		}
		set .@menu$,"";
		for(set .@i,0; .@i<getarraysize(.@items); set .@i,.@i+1)
			set .@menu$, .@menu$+getitemname(.@items[.@i])+((.@k)?" [1]":"")+":";
		callsub S_EnchantArmor, .@items[select(.@menu$)-1], .@j;
		end;
	}
	mes "I am in charge of Enchanting Armors. Simply put, I've been studying ways to power-up armor.";
	next;
	mes "[Apprentice Craftsman]";
	mes "If by any chance, you would want to enchant your armor, bring me 400,000 zeny and the armor you want to enchant and you are all set to go.";
	close;

S_EnchantArmor:
	set .@itemid,getarg(0);
	set .@failrate,getarg(1);
	mes "[Apprentice Craftsman]";
	if (countitem(.@itemid) == 1) {
		mes "Socket enchant will cost you 400,000 zeny. And there will be a random option enchanted. Of course, there is a chance of breaking your armor.";
		next;
		mes "[Apprentice Craftsman]";
		mes "First and most importantly.";
		mes "^ff5555Existing Refine Level of the Armor";
		mes "and Cards will be GONE.^000000";
		mes "Do you still want to try an Enchant?";
		next;
		if(select("Hmm... Let me think it over.:Go ahead.") == 1) {
			mes "[Apprentice Craftsman]";
			mes "Well, I can't blame you. Safety first, eh?";
			mes "Now you have a nice day.";
			close;
		}
		mes "[Apprentice Craftsman]";
		mes "Quite of an adventurer huh? Well, shall we?";
		close2;
		specialeffect2 EF_MAPPILLAR;
		if (Zeny < 400000) {
			mes "[Apprentice Craftsman]";
			mes "Sorry, but you don't have enough zeny.";
			close;
		}
		progressbar "ffff00",7;
		Zeny -= 400000;
		delitem .@itemid,1;
		switch (rand(1,.@failrate)) {
			case 1: set .@addpart,4702;break;
			case 2: set .@addpart,4712;break;
			case 3: set .@addpart,4722;break;
			case 4: set .@addpart,4732;break;
			case 5: set .@addpart,4742;break;
			case 6: set .@addpart,4752;break;
			case 7:
			case 8: set .@addpart,4701;break;
			case 9:
			case 10: set .@addpart,4711;break;
			case 11:
			case 12: set .@addpart,4721;break;
			case 13:
			case 14: set .@addpart,4731;break;
			case 15:
			case 16: set .@addpart,4741;break;
			case 17:
			case 18: set .@addpart,4751;break;
			case 19:
			case 20:
			case 21: set .@addpart,4700;break;
			case 22:
			case 23:
			case 24: set .@addpart,4710;break;
			case 25:
			case 26:
			case 27: set .@addpart,4720;break;
			case 28:
			case 29:
			case 30: set .@addpart,4730;break;
			case 31:
			case 32:
			case 33: set .@addpart,4740;break;
			case 34:
			case 35:
			case 36: set .@addpart,4750;break;
			default:
				specialeffect2 EF_PHARMACY_FAIL;
				mes "[Apprentice Craftsman]";
				mes "Well that's too bad.";
				mes "The requested equipment has failed to enchant.";
				close;
		}
		getitem2 .@itemid, 1, 1, 0, 0, 0, 0, 0, .@addpart;
	}
	else {
		mes "Hmm? There's nothing to be enchanted!";
		mes "Please come back with just ONE equipment to be enchanted.";
		close;
	}
}