From 9ef634559f3cde232586b1dc6fd00bea3f3d8e53 Mon Sep 17 00:00:00 2001
From: ai4rei <ai4rei@54d463be-8e91-2dee-dedb-b68131a5f0ec>
Date: Sun, 10 Jul 2011 06:17:06 +0000
Subject: * Merged changes from trunk [14827:14894/trunk].

git-svn-id: https://rathena.svn.sourceforge.net/svnroot/rathena/branches/renewal@14895 54d463be-8e91-2dee-dedb-b68131a5f0ec
---
 3rdparty/CMakeLists.txt | 54 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 3rdparty/CMakeLists.txt

(limited to '3rdparty/CMakeLists.txt')

diff --git a/3rdparty/CMakeLists.txt b/3rdparty/CMakeLists.txt
new file mode 100644
index 000000000..3e7cb4cc4
--- /dev/null
+++ b/3rdparty/CMakeLists.txt
@@ -0,0 +1,54 @@
+
+# macro to configure the use of local or system version of a package
+# Uses:
+#	HAVE_LOCAL_${name} - is local version available?
+#	${name}_LOCAL_LIBRARIES - libraries of the local version
+#	${name}_LOCAL_INCLUDE_DIRS - include directories of the local version
+#	HAVE_SYSTEM_${name} - is system version available?
+#	${name}_SYSTEM_LIBRARIES - libraries of the system version
+#	${name}_SYSTEM_INCLUDE_DIRS - include directories of the system version
+# Generates:
+#	WITH_LOCAL_${name} - use the local version of the package (only when local is available)
+#	WITH_${name} - use this package
+#	${name}_LIBRARIES - libraries
+#	${name}_INCLUDE_DIRS - include directories
+macro( CONFIGURE_WITH_LOCAL_OR_SYSTEM name )
+	unset( ${name}_LIBRARIES CACHE )
+	unset( ${name}_INCLUDE_DIRS CACHE )
+	if( HAVE_LOCAL_${name} )
+		set( WITH_LOCAL_${name} ON
+			CACHE BOOL "use local version of ${name}" )
+	else()
+		unset( WITH_LOCAL_${name} CACHE )
+	endif()
+	if( WITH_LOCAL_${name} )
+		message( STATUS "Configuring for local ${name}" )
+		set( ${name}_LIBRARIES ${${name}_LOCAL_LIBRARIES} )
+		set( ${name}_INCLUDE_DIRS ${${name}_LOCAL_INCLUDE_DIRS} )
+		message( STATUS "Configuring for local ${name} - done" )
+	elseif( HAVE_SYSTEM_${name} )
+		message( STATUS "Configuring for system ${name}" )
+		set( ${name}_LIBRARIES ${${name}_SYSTEM_LIBRARIES} )
+		set( ${name}_INCLUDE_DIRS ${${name}_SYSTEM_INCLUDE_DIRS} )
+		message( STATUS "Configuring for system ${name} - done" )
+	endif()
+	if( WITH_LOCAL_${name} OR HAVE_SYSTEM_${name} )
+		set( WITH_${name} ON
+			CACHE BOOL "use ${name}" )
+	else()
+		unset( WITH_${name} CACHE )
+	endif()
+	set( ${name}_LIBRARIES ${${name}_LIBRARIES}
+		CACHE PATH "${name} libraries" )
+	set( ${name}_INCLUDE_DIRS ${${name}_INCLUDE_DIRS}
+		CACHE PATH "${name} include directories" )
+	mark_as_advanced( ${name}_LIBRARIES )
+	mark_as_advanced( ${name}_INCLUDE_DIRS )
+endmacro( CONFIGURE_WITH_LOCAL_OR_SYSTEM )
+
+
+add_subdirectory( msinttypes )
+add_subdirectory( mt19937ar )
+add_subdirectory( mysql )
+add_subdirectory( pcre )
+add_subdirectory( zlib )
-- 
cgit v1.2.3-70-g09d2