009-2.gat,63,79,0	script	Olana	190,{

  if (FLAGS & FLAG_ROSSI_COMPLETED) goto L_FinalEnd;
  if (Rossy_Quest == 17 || Rossy_Quest == 18) goto L_End;


  if (Rossy_Quest >= 14 && Rossy_Quest <= 16) goto L_Julia;
  if (Rossy_Quest == 13) goto L_Best;
  if (Rossy_Quest == 12) goto L_Give;
  if (Rossy_Quest == 11) goto L_Allergic;
  if (Rossy_Quest == 10) goto L_BringRose;
  if (Rossy_Quest == 9) goto L_RC;
  if (Rossy_Quest == 8) goto L_Rose;
  if (Rossy_Quest >= 6 && Rossy_Quest < 8) goto L_BL;
  if (Rossy_Quest == 5) goto L_Bring;
  if (Rossy_Quest == 4) goto L_See;
  if (Rossy_Quest == 3) goto L_Worried;
  if (Rossy_Quest == 1 || Rossy_Quest == 2) goto L_Daughter;

  mes "[Olana]";
  mes "\"Hello. Usually guests don't come here.\"";
  next;
  mes "\"My name is Olana, my father owns this inn. I'm living in Tulimshar, but came to Hurnscald on vacation with my two young daughters, Rossy and Julia.\"";
  if (baselevel < 50) close;
  next;
  mes "\"I let my two lovely girls play in the woods nearby but they didn't come back yet!\"";
  next;
  mes "Olana suddenly looks very pale and starts to shiver.";
  next;
  mes "\"Oh, I have a bad feeling about this whole situation... If you go to the forest near the swamps, can you see if you find my daughters? I need to know if they are safe.\"";
  menu
    "Sure, I can do that.", -,
    "I am sorry, I don't usually go to this area", L_No;
  set Rossy_Quest, 1;
  close;

L_Daughter:
  mes "*Olana looks really worried... she seems about to burst into tears...*";
  if (Rossy_Quest == 1) close;
  next;
  menu
    "Wait, I saw Rossy, she is fine.", L_Help,
    "Hey, don't worry, I'm sure they'll be back soon.", L_No;

L_No:
  close;

L_Help:
  mes "[Olana]";
  mes "\"Oh yes? Is Rossy alright? That's good. I'm relieved. But what about Julia?\"";
  next;
  menu
    "I didn't find Julia yet, sorry", -;
  mes "\"Ok. They must be playing hide and seek. Thanks again... I can't express how grateful I am.\"";
  set Rossy_Quest, 3;
  close;

L_Worried:
  mes "*Olana smiles at you, trying to show some happiness, but her facial expression only conveys tension and preoccupation*";
  close;

L_See:
  if (gotcherry == 1) goto L_Task;
  if (countitem("cherry") < 10) goto L_Worried;
  menu
    "Hi, Rossy asked me to give you this. She says it is a gift from her and from Julia", -;
  mes "[Olana]";
  mes "\"Ohhh... How sweet... Sometimes Rossy impress me with her kindness. Here. You are spending so much time helping us, and we give nothing back. Take this as a small reward. \"";
  delitem "cherry", 10;
  getexp 1000, 0;
  set zeny, zeny + 1000;
  set gotcherry, 1;
  goto L_Task;

L_Task:
  mes "[Olana]";
  mes "\"I know I barely know you, but can I ask you for a small favor?\"";
  menu
    "Sure, tell me about it.", L_Cont,
    "No, sorry, I'm busy.", L_No;

L_Cont:
  mes "[Olana]";
  mes "\"Would you mind giving this letter to my little Rossy? Today is the last day for her final exam, and I know my daughter. If I don't remind her, she will surely forget about it and flunk the exam. I would deliver it myself, but I can't walk, my knees...\"";
  menu
    "Of course I can. Hand me the letter, I'll give it to Rossy as soon as I see her.", L_Let,
    "No, sorry, I'm not interested in that sort of task. Hand it to her yourself.", L_No;

L_Let:
  mes "[Olana]";
  set Rossy_Quest, 5;
  set gotcherry, 0;
  mes "\"Thank you again. Please, bring it to her as fast as you can.\"";
  close;

L_Bring:
  mes "[Olana]";
  mes "\"Please, bring this letter to my daughter as fast as you can.\"";
  close;

L_BL:
  mes "[Olana]";
  mes "\"Good, now she won't forget her final exam.\"";
  close;

L_Rose:
  menu
    "Hi, Rossy did great in the exam. David told me her potion was flawless.", -;
  mes "[Olana]";
  mes "\"Wow! Really? That is great! I would like to congratulate my little Rossy, would you help me?\"";
  menu
    "Just tell me what to do.", -,
    "No, I'm busy, maybe later.", L_No;
  mes "[Olana]";
  mes "\"Can you bring me 15 [Red Rose]s? I would like to give them to Rossy. I am sure she will love it!\"";
  menu
    "Ok, I will be back with the roses.", L_RG,
    "I'm allergic to roses, can't even touch them. Sorry.", L_No;

L_RG:
  if (Rossy_Quest == 8) set Rossy_Quest, 9;
  mes "[Olana]";
  mes "\"Please, bring me 15 [Red Rose]s as soon as you can.\"";
  close;

L_RC:
  if(countitem("redrose") < 15) goto L_RG;
  mes "[Olana]";
  set Rossy_Quest, 10;
  mes "\"Great job! Please hand them to my brilliant daughter, Rossy.\"";
  close;

L_BringRose:
  mes "[Olana]";
  mes "\"Now please hand them to my brilliant daughter, Rossy.\"";
  close;

L_Allergic:
  mes "[Olana]";
  mes "\"Did she like my present?\"";
  menu
    "Sure she did...", L_No,
    "Well, you should known that your daughter is allergic to roses.", -;
  set Rossy_Quest, 12;
  mes "[Olana]";
  mes "\"How stupid I am! Here, take some of my money and buy [Red Tulip]s instead, the same amount. Keep the flowers.\"";
  set zeny, zeny + 1500;
  next;
  mes "\"Please, tell Rossy I am really sorry. My mind was in Julia when I asked you to bring the red roses, they are her favorite.\"";
  menu
    "I will give her the tulips when I see her.", -;
  mes "[Olana]";
  mes "\"And don't forget to tell her that I'm really sorry.\"";
  close;

L_Give:
  mes "[Olana]";
  mes "\""+ strcharinfo(0) +", please, get 15 [Red Tulip]s and hand them to Rossy. Don't forget to tell her that I'm really sorry.\"";
  close;

L_Best:
  mes "[Olana]";
  mes "\"Thank you for your help "+ strcharinfo(0) +"!\"";
  close;

L_Julia:
  mes "[Olana]";
  mes "\"Oh no, I can't take this anymore. Something must have happened... Where is Julia? I want to know where she is! Please, find her "+ strcharinfo(0) +"!\"";
  close;

L_End:
  mes "[Olana]";
  mes "\"Where is Julia? I want to know where she is! Please, find her "+ strcharinfo(0) +"!\"";
  menu
    "She'll be back soon, trust me, I saved her from an evil spirit.", L_Found,
    "I didn't see her yet, sorry.", L_No;

L_Found:
  mes "[Olana]";
  if (Rossy_Quest == 17) set Rossy_Quest, 18;
  if (Rossy_Quest == 18) set Rossy_Quest, 19;
  mes "\"Thank you "+ strcharinfo(0) +", thank you! Here is a reward for you.\"";
  getexp 5000, 0;
  set zeny, zeny + 5000;
  if (Rossy_Quest == 19) goto L_Clear;
  close;

L_Clear:
  set Rossy_Quest, 0;
  set cavefights, 0;
  set FLAGS, FLAGS | FLAG_ROSSI_COMPLETED;
  close;

L_FinalEnd:
  mes "[Olana]";
  mes "*The mother is calmly waiting her daughters to come back for dinner.*";
  close;

}