030-2,25,35,0	script	Vellamo	NPC328,{
    @halloween_npc_id = $@halloween_npc_vellamo;
    callfunc "TrickOrTreat";
    callfunc "XmasStates";

    if($@xmas_time)
        goto L_XmasMain;
    goto L_OffSeason;

L_OffSeason:
    mes "[Vellamo]";
    mes "\"Candy Stock is built back up. Though... the more we store the more they want...\"";
    goto L_close;

L_XmasMain:
    if (XMASTIME & $@xmas_helper_bit_storage) goto L_Candy;
    if (@xmas_helper_bit) goto L_Helping;

    mes "[Vellamo]";
    mes "\"Sorry, too busy to chat right now. The chief has got me working overtime for the holidays.\"";
    close;

L_Helping:
    mes "[Vellamo]";
    mes "\"Oh, hello. Visitors usually don't come down here in the basement. Here we store several things, materials for the presents, the finished presents, supplies.\"";
    menu
        "Nice. I have to go.", L_close,
        "Do you need help with anything?", L_Next;

L_Next:
    mes "[Vellamo]";
    mes "\"Oh? You want to help us? Actually, there is one thing you could do. Did you see those weird slimes out there on the snow fields? Argh, I hate those creatures, last year they invaded the entire basement...\"";
    next;
    mes "\"However, this year they tried again, but I was able to hold them off. They just managed to devour most of our candy supplies.\"";
    next;
    mes "\"So in case you find some of the Candies, feel free to bring them back. Ismo will give you some reward for them.\"";
    XMASTIME = XMASTIME | ($@xmas_helper_bit_storage);
    goto L_close;

L_Candy:
    mes "[Vellamo]";
    mes "\"Ah, welcome back. When you have found some of the candy, please give it to Ismo.\"";
    goto L_close;

L_close:
    close;
}

030-2,33,29,0	script	Ismo	NPC329,{
    callfunc "XmasStates";

    if(($@xmas_time) && (XMASTIME & $@xmas_helper_bit_storage))
        goto L_Helping;
    goto L_OffSeason;

L_OffSeason:
    mes "[Ismo]";
    mes "\"Hello. I'm helping Vellamo. He's the storage administrator.\"";
    goto L_close;

L_Helping:
    mes "[Ismo]";
    mes "\"Did you get back some candy from the slimes?\"";
    next;
    menu
        "Give " + $@xmas_good_friendly_name$, L_GoodCandy,
        "Give " + $@xmas_bad_friendly_name$ + "(What? how mean!).", L_BadCandy;

L_BadCandy:
    @dq_level = $@xmas_bad_level;
    @dq_cost = $@xmas_bad_cost;
    @dq_count = $@xmas_bad_count;
    @dq_name$ = $@xmas_bad_name$;
    @dq_friendly_name$ = $@xmas_bad_friendly_name$;
    @dq_money = $@xmas_bad_money;
    @dq_exp = $@xmas_bad_exp;

    callfunc "DailyQuest";
    if (countitem(@dq_name$) < @dq_count)
        goto L_close;
    @karma_bonus = $@xmas_karma_bonus;
    callfunc "XmasNaughty";
    goto L_close;

L_GoodCandy:
    @dq_level = $@xmas_good_level;
    @dq_cost = $@xmas_good_cost;
    @dq_count = $@xmas_good_count;
    @dq_name$ = $@xmas_good_name$;
    @dq_friendly_name$ = $@xmas_good_friendly_name$;
    @dq_money = $@xmas_good_money;
    @dq_exp = $@xmas_good_exp;

    callfunc "DailyQuest";
    if (countitem(@dq_name$) < @dq_count)
        goto L_close;
    @karma_bonus = $@xmas_karma_bonus;
    callfunc "XmasNice";
    goto L_close;

L_close:
    close;
}