009-2,148,25,0	script	Doctor	NPC107,{
    @inspector = ((QUEST_Hurnscald & NIBBLE_3_MASK) >> NIBBLE_3_SHIFT);

    if (isequipped(AxeHat)) goto L_Axe;
    if (isequipped(Eyepatch)) goto L_EyePatch;

    mesn;
    mes "\"Hello, can I help you?\"";
    next;

    if (@inspector == 1)
        menu
            "I think I am sick!", L_Cure,
            "No, I feel fine.", L_Next,
            "Have you seen anything strange in town? Anything that might have to do with the robberies?", L_NohMask;
    menu
        "I think I am sick!", L_Cure,
        "No, I feel fine.", L_Next;

L_Next:
    mesn;
    mesq l("Then please stop wasting my precious time.");
    goto L_close;

L_Cure:
    mesn;
    if (sc_check(SC_POISON) || sc_check(SC_DPOISON))
        goto L_CurePoison;
    mesc l("The doctor examines you briefly.");
    mesq l("Nonsense! You look fine and dandy to me. All you need is a bit more exercise and fresh fruit in your diet!");
    goto L_close;

L_CurePoison:
    mesq l("Well, well, well! Look at all those green bubbles coming out of your head; that looks like poisoning to me!  Did you eat something rotten?");
    next;
    mesn;
    mesc l("The doctor pulls out a syringe and fills it with a white liquid from a jar on his desk.");
    mesq l("Now hold still, this won't hurt a bit...");
    next;
    mesn;
    sc_end(SC_POISON);
    sc_end(SC_DPOISON);
    sc_end(SC_SLOWPOISON);
    mes "*Ouch!*";
    mes "\"Next time, be more careful!  Make sure to cook any meats before you eat them, and don't eat fish once it starts to smell.\"";
    goto L_close;

L_Axe:
    mesn;
    mes "\"Oh my, what happened to you?\"";
    next;
    mesn;
    mes "\"Wait. Thats just a fake. Shame on you!\"";
    goto L_close;

L_EyePatch:
    mesn;
    mes "\"Would you like a glass eye to replace that eye patch you have? We just got a whole load of them in today. I'll even let you keep the patch as a souvenir.\"";
    next;
    menu
        "Yes, please.", L_EyePatch_GlassEye,
        "No thank you", L_Next1;

L_Next1:
    mesn;
    mes "\"If you change your mind, please come back and see me.\"";
    goto L_close;

L_EyePatch_GlassEye:
    mesn;
    mes "\"Now, where did I put that box of eyes...\"";
    mes "He goes off to look for them and comes back empty handed.";
    next;
    mesn;
    mes "\"I can't seem to find where I put that box. You should come back later, I may have found them by then.\"";
    goto L_close;

L_NohMask:
    mesn;
    mes "\"No, I haven't seen anything.\"";
    goto L_close;

L_close:
    @inspector = 0;
    close;
}