001-2,92,88,0	script	David	NPC120,{
    @Potion_EXP = 2000;

    if (Rossy_Quest == 17) goto L_FinalEnd;
    if (Rossy_Quest == 14) goto L_Julia;
    if (Rossy_Quest >= 8) goto L_Done;

    mes "[David]";
    mes "\"Learning magic is hard...\"";
    if (Rossy_Quest == 7) goto L_Help;
    close;

L_Help:
    menu
        "Do you know Rossy?", L_Set,
        "I can tell, it is hard.", L_No;

L_Set:
    mes "[David]";
    mes "\"Yes, I do. I am her teacher. Actually, that reminds me about her final exam... she didn't hand in her potion yet. Time is running out.\"";
    menu
        "A potion? Oh, uhm... Strange kind of exam. Bye.", L_No,
        "Right, I have her potion in my pocket. She asked me to bring it to you. Here it is.", L_Next;

L_Next:
    mes "[David]";
    mes "\"Let me see.\"";
    Rossy_Quest = 8;
    mes "\"This potion is... perfect! Tell Rossy that she successfully made her potion; it is flawless!\"";
    getexp @Potion_EXP, 0;
    close;

L_Done:
    mes "[David]";
    mes "\"I am really happy that my best student successfully passed her exam!\"";
    close;

L_No:
    close;

L_Julia:
    mes "[David]";
    mes "\"I heard Rossy's sister got kidnapped. We're counting on you to find her!\"";
    next;
    mes "\"If you do find her, talk to her sister and her mother.\"";
    close;

L_FinalEnd:
    mes "[David]";
    mes "Well done! Thanks for finding Julia!";
    close;
}