// Evol scripts.
// Authors:
//    The Mana World Team
// Co-Authors:
//    gumi
//    Qwerty Dragon
//    Reid
//    WildX
// Description:
//    7 main rules of The Mana World

function	script	GameRules	{
    narrator getarg(0, 0),
        l("1. ##BDo not AFK bot##b, this means you are not allowed to perform any AFK (away from keyboard) activity, apart from standing idle."),
        l("2. ##BDo not use offensive/rude language##b in the chats or in your character(s) name(s)."),
        l("3. ##BDo not spam/flood other players.##b This includes chat spam and spam by trade requests."),
        l("4. ##BSpeak only English in public areas.##b You can speak whatever language you want through whispers or whenever everyone in the area can speak said language."),
        l("5. ##BDo not beg others##b for money, items or favours of any kind. If you want to ask for something, do it politely and only once. Try not to annoy other players."),
        l("6. ##BDo not multibox.##b You are not allowed to engage in combat while controlling more than one character at a time."),
        l("7. ##BFollow the [@@https://policies.themanaworld.org/tsc|TMW Social Convention@@]##b (TSC)."),
        l("In the event that the rules diverge from [@@https://policies.themanaworld.org/game-rules|policies.themanaworld.org@@], the later version takes priority.");
    if (SERVER_USES_VAULT) {
        mesc l("Note: You are NOT allowed to have multiple Vault accounts.");
        if (getarg(0, 0) & S_LAST_NEXT)
            next;
    }
    return;
}


-	script	@rules	32767,{
    end;

    function read_book {
        narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
            l("This book outlines the laws of every city and holding in Gasaron."),
            l("The first page contains the universal rules that have been agreed upon throughout the land.");

        GameRules S_NO_NPC_NAME | S_LAST_NEXT;

        narrator S_NO_NPC_NAME,
            l("The next page begins to list the complex trading laws of the City of Esperia"),
            l("All this seems unimportant to you right now.");
        close;
    }

OnCall:
    GameRules;
    close;

OnUseBook:
    if (openbook())
        read_book;
    closeclientdialog();
    close;

OnShelfUse:
    if (openbookshelf())
        read_book;
    closeclientdialog();
    close;

OnInit:
    .book_name$ = "The Book of Laws";
    bindatcmd "rules", "@rules::OnCall", 0, 2, 0;
}