// Evol scripts.
// Author:
//    Reid
// Description:
//    Librarian

001-2-6,52,28,0	script	Leonard	NPC_LEONARD,{

    function esperia_city
    {
        speech S_FIRST_BLANK_LINE,
            l("You have put your finger on it, I am not."),
            l("I grew up and lived a good while in Esperia, the capital city."),
            l("This place is surrounded by two very important elements: academia and the arts. I was surrounded by theater, music, dance, museums..."),
            l("I had a great childhood in Esperia!"),
            l("It was wonderful.");

        emotion E_HAPPY;

        return;
    }

    function need_help
    {
        speech S_LAST_NEXT,
            l("Do you need help with something?");

        switch (select(l("What kinds of books are there here?"),
                       l("Are you a native from Artis?"),
                       l("Nothing.")))
        {
            case 1:
                closeclientdialog;
                npctalk3 l("You can find novels and poems on this floor.");
                break;
            case 2:
                esperia_city();
                break;
            case 3:
                closeclientdialog;
                npctalk3 l("Good day to you!");
        }
        return;
    }

    function not_so_loud
    {
        npctalkonce l("This floor is reserved for quiet reading, don't speak too loud.");

        return;
    }

    function miracle
    {
        npctalkonce l("The miracle is this: the more we share, the more we have.");

        return;
    }

    function logic_wisdom
    {
        npctalkonce l("Logic is the beginning of wisdom, not the end.");

        return;
    }

    switch (rand(4))
    {
        case 0:
            logic_wisdom();
            break;
        case 1:
            miracle();
            break;
        case 2:
            not_so_loud();
            break;
        case 3:
            need_help();
            break;
    }

    close;

OnInit:
    .bodytype = BODYTYPE_3;
    .distance = 2;
    end;
}