// Evol scripts.
// Authors:
//    Reid
// Description:
//    Librarian

001-2-4,27,33,0	script	Robin	NPC_ROBIN,{

    function need_help
    {
        speech 4,
            l("Do you need help with something?");

        switch (select(l("What kinds of books are there here?"),
                       l("Nothing.")))
        {
            case 1:
                closedialog;
                npctalk3 l("Mostly manuals and tutorials but you won't find out until you open one!");
                break;
            case 2:
                closedialog;
                npctalk3 l("Good day to you!");
        }
        return;
    }

    function mythologise_people
    {
        npctalkonce l("In Artis they really do mythologise people when they die.");

        return;
    }

    function no_matter_what
    {
        npctalkonce l("No matter what people tell you, words and ideas can change the world.");

        return;
    }

    function outside_inside
    {
        npctalkonce l("What counts in a book is like so many things, not what is on the outside, but what is on the inside.");

        return;
    }

    function kaizei_manuscripts
    {
        npctalkonce l("An explorer left behind some incomplete manuscripts about the people and dangers in the land of Kaizei.");

        return;
    }

    switch (rand(5))
    {
        case 0:
            no_matter_what();
            break;
        case 1:
            mythologise_people();
            break;
        case 2:
            outside_inside();
            break;
        case 3:
            kaizei_manuscripts();
            break;
        case 4:
            need_help();
            break;
    }

    close;

OnInit:
    .sex = G_MALE;
    .distance = 2;
    end;
}