// TMW 2 Script
// Author:
//  Jesusalva
//  Micksha
// Description:
//  Controls sewers.
//  FIXME: The warps back should only work if treasure was found
//  Spawn monsters and respawns them.

// A simple random treasure chest - to be sure players were introduced to this
// awesome system. Same rules as any treasure box still applies.
042-6,65,89,0	script	#chest_0426	NPC_CHEST,{
    function monster0426;
	KamelotTreasure(8);
	specialeffect(.dir == 0 ? 24 : 25, AREA, getnpcid()); // closed ? opening : closing
	close;

OnInit:
	.distance = 2;
	end;

OnInstanceInit:
    // Yes, we just hope it works out of box
    explode(.@map$, .map$, "@");
    .@g=atoi(.@map$[1]);
    if (.@g < 1) {
        debugmes "[ERROR] [KAMELOT] Unable to spawn for Kamelot %s", .map$;
        debugmes "[ERROR] [KAMELOT] Using dummy data (returned: %d)", .@g;
        .@g=0;
    }
    debugmes "Spawning monsters for guild %d", .@g;
    .@mx=getguildavg(.@g);
    monster0426(1, 20, 20, 115, 100, .@mx);
    monster0426(4, 20, 51,  51,  71, .@mx);
    monster0426(5, 85, 56, 115, 100, .@mx);
    monster0426(2, 79, 40,  97,  52, .@mx);
    monster0426(5, 51, 20,  80,  50, .@mx);
    KamelotBoss("042-6", 74, 80, .@mx+1, .name$);

    // Boss monster
    // TODO

    // Neutral monsters
    areamonster(.map$, 20, 20, 115, 100, strmobinfo(1, YellowSlime), YellowSlime, 5);
    areamonster(.map$, 20, 20, 115, 100, strmobinfo(1, ManaGhost), ManaGhost, max(1, .@mx/10));

    // Bonus monsters
    if (!rand2(2))
        areamonster(.map$, 20, 20, 115, 100, strmobinfo(1, MagicBif), MagicBif, 1);
    if (!rand2(2))
        areamonster(.map$, 20, 20, 115, 100, strmobinfo(1, SilverChest), SilverChest, 1);
    if (!rand2(2))
        areamonster(.map$, 20, 20, 115, 100, strmobinfo(1, BronzeChest), BronzeChest, 1);
    // Next time I promise a Whirly Bird >.>
    end;

OnKillMob:
    if (!playerattached())
        goto OnRespawn;
    // Maybe a reward is due
    .@g=getcharid(2);
    if (.@g < 1) percentheal -100, -100;
    getexp $KAMELOT_MX[.@g]*7, $KAMELOT_MX[.@g]*4;
    .@delay=max(3000, 21000-$KAMELOT_PC[.@g]*1000);
    // FALLTHROUGH

OnRespawn:
    .@delay=(.@delay ? .@delay : 3000);
    sleep(.@delay);
    // Yes, we just hope it works out of box
    explode(.@map$, .map$, "@");
    .@g=atoi(.@map$[1]);
    if (.@g < 1) {
        debugmes "[ERROR] [KAMELOT] Unable to respawn for Kamelot %s", .map$;
        .@g=0;
    }
    monster0426(1, 20, 20, 115, 100, $KAMELOT_MX[.@g]);
    end;

function monster0426 {
    .@label$=instance_npcname(.name$)+"::OnKillMob";
    .@gcount=getarg(0);
    .@x1=getarg(1);
    .@y1=getarg(2);
    .@x2=getarg(3);
    .@y2=getarg(4);
    .@avg=getarg(5);
    .@m$=instance_mapname("042-6");
    //debugmes "Total %d, map %s (power %d)", .@gcount, .@m$, .@avg;
    freeloop(true);
    for (.@i=0; .@i < .@gcount; .@i++) {
        .@mobId=any(CursedSoldier, CursedArcher); // 50-50 ratio
        .@mob=areamonster(.@m$, .@x1, .@y1, .@x2, .@y2, strmobinfo(1, .@mobId), .@mobId, 1, .@label$);
        // Reconfigure the monster
        setunitdata(.@mob, UDT_LEVEL, .@avg+1);
        setunitdata(.@mob, UDT_STR, 1+.@avg*6/10);
        setunitdata(.@mob, UDT_AGI, 1+.@avg*5/10);
        setunitdata(.@mob, UDT_VIT, 1+.@avg*5/10);
        setunitdata(.@mob, UDT_INT, 1+.@avg*6/10);
        setunitdata(.@mob, UDT_DEX, 1+.@avg*6/10);
        setunitdata(.@mob, UDT_LUK, 1+.@avg*5/10);
        setunitdata(.@mob, UDT_ADELAY, 1372);
        setunitdata(.@mob, UDT_ATKRANGE, (.@mobId == CursedArcher ? any(6,7) : any(1,2)));
        // Battle Status
        setunitdata(.@mob, UDT_MAXHP,    .@avg*40);
        setunitdata(.@mob, UDT_HP,       .@avg*40);
        setunitdata(.@mob, UDT_ATKMIN,   .@avg*52/10);
        setunitdata(.@mob, UDT_ATKMAX,   .@avg*72/10);
        setunitdata(.@mob, UDT_DEF,      1+.@avg*12/10);
        setunitdata(.@mob, UDT_MDEF,     1+.@avg*8/10);
        setunitdata(.@mob, UDT_HIT,      .@avg*6); // Advised: x3
        setunitdata(.@mob, UDT_FLEE,     .@avg*45/10); // Advised: x4
        // Critical calculation
        .@min=15;
        .@max=max(.@min, min(40, .@avg/3));
        setunitdata(.@mob, UDT_CRIT,     rand2(.@min, .@max));
        // Loop through
    }
    freeloop(false);
    return;
    }

}