// TMW2 scripts.
// Authors:
//    Jesusalva
// Description:
//    Gemini Sisters Quest - Forest & Desert Stage

034-1,67,48,0	script	Fake Manastone	NPC_MANA_STONE,{
    if (instance_id() < 0 || getcharid(1) < 1) end;
    GeminiCheck(1);
    mesc l("This is a weird stone. It looks like a Mana Stone from afar, but anyone can tell it is fake.");
    if (strcharinfo(0) != getpartyleader(getcharid(1))) {
        mesc l("It may be dangerous. I better ask %s to check it instead.", getpartyleader(getcharid(1)));
        close;
    }
    switch ('STATUS) {
    case 1:
    case 2:
        mesc l("It seems to be a mechanism of some kind, but it is missing a Runestone.");
        mesc l("Maybe one of the slimes dropped it.");
        'STATUS = 2;
        break;
    case 3:
        mesc l("You insert the Runestone on it and hear a sound.");
        mesc l("Something changed; We should see what is.");
        'STATUS = 4;
        break;
    default:
        mesc l("I already did everything I could with this. What am I waiting for?");
        break;
    }
    close;

OnInit:
    .distance = 2;
    end;
}

034-1,66,45,0	script	#GeminiExit	NPC_HIDDEN,0,0,{
    end;
OnTouch:
    if (instance_id() < 0 || getcharid(1) < 1) end;
    GeminiCheck(1);
    if ('STATUS < 4) {
        dispbottom l("There seems to be sort of lock preventing you from passing.");
        end;
    }
    slide 118, 115;
    end;
}