// TMW-2 Script.
// Author:
//    Jesusalva
// Notes:
//    Generic Guard from the Alliance

025-2,108,23,0	script	Alliance Guard	NPC_BRGUARD_BOW,{
    .@q=getq(General_Narrator);
    if (.@q >= 21)
        goto L_ShortSummary;
    inventoryplace PurificationPotion, 3, ElixirOfLife, 1;
    setpcblock(PCBLOCK_HARD, true);
    mesc l("STORY MODE ENABLED. Monsters won't attack you, so you can read without worries."), 1;
    next;
    mesn;
    mesq l("Hey %s, I was informed about your arrival. You are here, good!", strcharinfo(0));
    next;
    mesn;
    mesq l("You see the gates over there? This is the World's Edge. The land which never had a settlement. How. is. there. a. town?!");
    next;
    mesn;
    mesq l("Not only that, but it is swarming with monsters. Something is really wrong here. From our scouts which went in there, only one returned.");
    next;
    mesn;
    mesq l("So, what to expect? Past this gate is a panthom town and some steel grating. Past the grating is the actual Impregnable Fortress.");
    next;
    mesn;
    mesq l("We found several interest points inside, like some mines with the most precious ores in the world - like %s and even %s - along very powerful monsters. Unfortunately, it is partly flooded.", getitemlink(PlatinumOre), getitemlink(MylarinDust));
    next;
    mesn;
    mesq l("We also found a small fortress and a small gothic building which might have important clues on your journey. Our first task, therefore, should be recapturing this town from our enemies!");
    next;
    mesn;
    mesq l("Once that is done, the Alliance's staff will set several stands with the most important services you might need, like banking, inside the town central area.");
    next;
    mesn;
    mesq l("Monsters, however, keep coming from the Impregnable Fortress. They always come on %s, although we have no idea why.", b(l("Tuesdays")));
    next;
    mesn;
    mesq l("So, %s, I know you have other priorities. I don't even know why you are here - for riches? For glory, for fame? To save the world? To find out about your past? To talk with me because, well, I am just *that* cool? All of the above? Perhaps something else?", strcharinfo(0));
    next;
    mesn;
    mesq l("But we cannot ignore the threat this imposes to us. You might not know our world's history, but this place should never be inhabited or else...");
    next;
    mesn;
    .@find$=l("Please find %s - we will need the current world's hero to conduct the siege on the Fortress Town.", $MOST_HEROIC$);
    .@sieg$=l("You are our hero- Please assemble a team of adventurers and raid the Fortress Town.");
    mesq l("%s But please be quick! I feel this world doesn't have much time left!", (strcharinfo(0) == $MOST_HEROIC$ ? .@sieg$ : .@find$));
    next;
    mesn;
    mesq l("Here, take this %s and these %s and good luck!", getitemlink(ElixirOfLife), getitemlink(PurificationPotion));
    next;
    mesc b(l(".:: Main Quest ::.")), 3;
    msObjective($FORTRESS_STATE, l("* Invade the Fortress Town"));
    msObjective(false, l("* Find clues"));
    msObjective(false, l("* (optional) Save the world!"));
    next;
    setpcblock(PCBLOCK_HARD, false);
    setq General_Narrator, 21;
    getitem PurificationPotion, 3;
    getitem ElixirOfLife, 1;
    closeclientdialog;
    legiontalk();
    close;

L_ShortSummary:
    .@open$=l("We have set some stalls which should be useful if you plan into raiding the Impregnable Fortress.");
    .@lock$=l("It is locked but %s should be able to coordinate a raid on it.", $MOST_HEROIC$);
    mesn;
    mesq l("Past this point is the Fortress Island. %s Even so, be careful, the town should not exist.", ($FORTRESS_STATE ? .@open$ : .@lock$));
    close;
}