// TMW2 scripts.
// Authors:
//    Jesusalva
//    TMW Org.
// Description:
//    Workers which produces pages
//    helperM*

// NivalisQuest_BlueSage STRUCTURE
//  FIELD 1:
//      INVESTIGATION
//  FIELD 2:
//      BOOK MAKING QUEST
//      1 - Illustrations delivered (BS_PMINK)
//      2 - Bindings delivered (BS_PMBINDING)
//      4 - Pages delivered (BS_PMPAGE)
//      8 - Glue delivered (BS_PMGLUE)
//      =15: All items delivered
//  FIELD 3:
//      SLIME HUNTING QUEST

020-7-1,34,56,0	script	Eevert	NPC_BLUESAGEWORKER_MA,{
    function askQuestion;
    .@q2=getq2(NivalisQuest_BlueSage);
    mesn;
    if (.@q2 & BS_PMINK)
        mesq l("Thanks for your help with the inks! Now I'll be able to fulfill my tasks adequately. Some of these books were really valuable, and it's important to recreate them as good as possible.");
    else
        mesq l("Mh. I wonder how I'm expected to perform my task with this meager equipment. The new books will look pathetic.");

    // Begin here
    askQuestion();
    .@q2=getq2(NivalisQuest_BlueSage);
    mes "";
    mesn;
    mesq l("I'm doing the covers and illustrations for the new books we create from the pieces of the old ones.");
    next;
    mesn;
    mesq l("But due to all of the chaos from when the slimes escaped, most of the phials of colored ink were broken. How am I supposed to do the illustrations without color?");
    next;
    mesn;
    mesq l("I could make ink myself, but I am lacking some material...");
    next;
    mes l("@@/@@ @@", countitem(CobaltHerb),    50, getitemlink(CobaltHerb));
    mes l("@@/@@ @@", countitem(GambogeHerb),   50, getitemlink(GambogeHerb));
    mes l("@@/@@ @@", countitem(AlizarinHerb),  50, getitemlink(AlizarinHerb));
    mes l("@@/@@ @@", countitem(ArtichokeHerb), 50, getitemlink(ArtichokeHerb));
    mes l("@@/@@ @@", countitem(MauveHerb),     50, getitemlink(MauveHerb));
    mes l("@@/@@ @@", countitem(MaggotSlime),   10, getitemlink(MaggotSlime));
    mes l("@@/@@ @@", countitem(DuckFeather),   1, getitemlink(DuckFeather));
    next;
    mesn;
    mesq l("Hehe... Some material... %%5");
    next;
    select
        l("Uh... Yeah, that's not funny."),
        l("Worry not, I have them with me.");
    mes "";
    if (@menu == 1) {
        mesn;
        mesq l("I agree with you. Most of these materials can't even be found on Nivalis.");
        next;
        mesn;
        mesq l("I guess I'll need to try to work with whatever ink is left until the supplies arrive next month...");
        close;
    }
    if (countitem(CobaltHerb)   < 50 ||
        countitem(GambogeHerb)  < 50 ||
        countitem(AlizarinHerb) < 50 ||
        countitem(ArtichokeHerb) < 50 ||
        countitem(MauveHerb)    < 50 ||
        countitem(MaggotSlime)  < 10 ||
        countitem(DuckFeather)  < 1) {
        mesn;
        mesq l("Do you know how to count, maggot? %%5");
        next;
        mesn;
        mesq l("You should be ASHAMED of yourself, you liar.");
        close;
    }
    delitem CobaltHerb,     50;
    delitem GambogeHerb,    50;
    delitem AlizarinHerb,   50;
    delitem ArtichokeHerb,  50;
    delitem MauveHerb,      50;
    delitem MaggotSlime,    10;
    delitem DuckFeather,     1;
    setq2 NivalisQuest_BlueSage, .@q2|BS_PMINK;
    getexp 3535, 215; // 20% from references, rounded up. It's part of main story.
    // is present. REMEMBER THIS IS A LEVEL 36/16 QUEST, REGARDLESS IF EVERYONE DECIDES
    // TO DO IT AT LEVEL 40. Exp reward will not change. It's main story, too.
    // Besides, it gives Job Experience, which is not common.
    mesn;
    mesq l("Wonderful! Now I can prepare the ink for magnificent illustrations! You're very generous.");
    close;

function askQuestion {
    .@qs=BSQuestion(getq(NivalisQuest_BlueSage));
    do {
        .@q=getq(NivalisQuest_BlueSage);
        .@q2=getq2(NivalisQuest_BlueSage);
        next;
        select
            rif(!(.@q2 & BS_PMINK), l("What is your problem?")),
            rif(.@qs & BS_QVISITOR, l("Do you know anything about the strange visitor?")),
            rif(.@qs & BS_QHELPER, l("What's your opinion of Peetu and his work?")),
            any(l("I need to leave."), l("See you."), l("Bye."), l("Not my problem."));
        mes "";
        switch (@menu) {
            case 2:
                mesn;
                mesq l("A visitor? I don't really pay attention to visitors, unless it's someone notable.");
                break;
            case 3:
                mesn;
                mesq l("Ah, Peetu. I really appreciate his sense for high quality work. The requirements to become a helper of a sage are already high, but Peetu is outstanding. He has a talent for magic and combined with his diligence, it's quite remarkable.");
                next;
                mesn;
                mesq l("That's why I'm really confused about this situation, since he was the one performing the sealing of the slimes. I wonder what went wrong.");
                if (is_between(4, 7, .@q))
                    setq1 NivalisQuest_BlueSage, .@q + 3;
                break;
            case 4:
                close;
        }
    } while (@menu != 1);
    return;
}

OnInit:
    .sex=G_MALE;
    .distance=5;
    npcsit;
    end;
}
























020-7-1,44,56,0	script	Janika	NPC_BLUESAGEWORKER_FA,{
    function askQuestion;
    .@q2=getq2(NivalisQuest_BlueSage);
    mesn;
    if (.@q2 & BS_PMBINDING)
        mesq l("Thanks for the Silk Cocoons. With these the new books are going to be exquisite.");
    else
        mesq l("This is going to be difficult... oh, hello. I'm working on recreating some of the books that were destroyed.");

    // Begin here
    askQuestion();
    .@q2=getq2(NivalisQuest_BlueSage);
    mes "";
    mesn;
    mesq l("I need @@/@@ @@ for the book covers and binding of some of the more valuable books we're trying to recreate.", countitem(SilkCocoon), 60, getitemlink(SilkCocoon));
    next;
    mesn;
    mesq l("You wouldn't happen to have them, would you?");
    if (countitem(SilkCocoon) < 60)
        close;
    next;
    if (askyesno() == ASK_NO) {
        mes "";
        mesn;
        mesq l("That's a pity.");
        close;
    }
    mes "";

    delitem SilkCocoon,     60;
    setq2 NivalisQuest_BlueSage, .@q2|BS_PMBINDING;
    getexp 3535, 215; // 20% from references, rounded up. It's part of main story.
    // is present. REMEMBER THIS IS A LEVEL 36/16 QUEST, REGARDLESS IF EVERYONE DECIDES
    // TO DO IT AT LEVEL 40. Exp reward will not change. It's main story, too.
    // Besides, it gives Job Experience, which is not common.
    mesn;
    mesq l("Excellent! This is exactly what I need. Thanks a lot. I'll tell Nikolai about your generosity.");
    close;

function askQuestion {
    .@qs=BSQuestion(getq(NivalisQuest_BlueSage));
    do {
        .@q=getq(NivalisQuest_BlueSage);
        .@q2=getq2(NivalisQuest_BlueSage);
        next;
        select
            rif(!(.@q2 & BS_PMBINDING), l("Can I help you?")),
            rif(.@qs & BS_QVISITOR, l("Do you know anything about the strange visitor?")),
            rif(.@qs & BS_QHELPER, l("What's your opinion of Peetu and his work?")),
            any(l("I need to leave."), l("See you."), l("Bye."), l("Good luck."));
        mes "";
        switch (@menu) {
            case 2:
                mesn;
                mesq l("Oh, I know who you mean! That impertinent person came over in the workshop area and fiddled about with all kinds of things here! Such a rude person! Didn't he understand that we had delicate things going on here? We had to send him back to the library area several times.");
                next;
                mesn;
                mesc l("She shakes her head.");
                mesq l("Sometimes I think it'd be better not to allow visitors here. But Nikolai set a high value on keeping contact with the population. Politics.");
                // It's safe in this context, don't worry
                if (.@q % 3 == 0)
                    setq1 NivalisQuest_BlueSage, .@q + 1;
                break;
            case 3:
                mesn;
                mesq l("Mh, I don't know him closely.");
                break;
            case 4:
                close;
        }
    } while (@menu != 1);
    return;
}
OnInit:
    .sex=G_FEMALE;
    .distance=5;
    end;
}
























020-7-1,45,31,4	script	Kullervo	NPC_BLUESAGEWORKER_MA,{
    npctalk3 l("I make book pages with... something.");
    goodbye;
    end;

OnInit:
    .sex=G_MALE;
    .distance=5;
    npcsit;
    end;
}
























020-7-1,36,31,4	script	Santeri	NPC_BLUESAGEWORKER_MA,{
    function askQuestion;
    .@q2=getq2(NivalisQuest_BlueSage);
    mesn;
    if (.@q2 & BS_PMGLUE)
        mesq l("Thanks to you, our glue supply is replenished and we can repair those books.");
    else
        mesq l("Welcome. Are you an adventurer? I could use some help.");

    // Begin here
    askQuestion();
    .@q2=getq2(NivalisQuest_BlueSage);
    mes "";
    mesn;
    mesq l("You see, we're working on repairing all of the damaged books and creating new ones for those that were lost.");
    next;
    mesn;
    mesq l("Therefore we need a lot of glue, but our supplies are nearly used up. I need @@/@@ @@ as ingredient to make new glue.", countitem(WolvernTooth), 3, getitemlink(WolvernTooth));
    next;
    mesn;
    mesq l("Do you have that? I have the other materials but I couldn't get it... @@ are too dangerous, they are level @@ monsters.", getmonsterlink(Wolvern), strmobinfo(3,Wolvern));
    if (countitem(WolvernTooth) < 3)
        close;
    next;
    if (askyesno() == ASK_NO) {
        mes "";
        mesn;
        mesq l("That's a pity.");
        close;
    }
    mes "";

    delitem SilkCocoon,     60;
    setq2 NivalisQuest_BlueSage, .@q2|BS_PMGLUE;
    getexp 3535, 215; // 20% from reference levels 36/16. It's part of main story.
    // Exp reward will not change. It applies to Job Exp on same rate.
    mesn;
    mesq l("Great! Thank you!");
    close;

function askQuestion {
    .@qs=BSQuestion(getq(NivalisQuest_BlueSage));
    do {
        .@q=getq(NivalisQuest_BlueSage);
        .@q2=getq2(NivalisQuest_BlueSage);
        next;
        select
            rif(!(.@q2 & BS_PMGLUE), any(l("Can I help you?"), l("I am. What heroic action is needed?"))),
            rif(.@qs & BS_QVISITOR, l("Do you know anything about the strange visitor?")),
            rif(.@qs & BS_QHELPER, l("What's your opinion of Peetu and his work?")),
            any(l("I need to leave."), l("See you."), l("Bye."), l("I'm just a lurker."));
        mes "";
        switch (@menu) {
            case 2:
                mesn;
                mesq l("There was a visitor with a mask? I didn't notice. You see, I spend most of my time in the workshop, and concentrate on my work. There are other helpers who attend to the visitors. And hopefully keep them from disturbing my concentration.");
                break;
            case 3:
                mesn;
                mesq l("Oh, that's an interesting question. I was really surprised when I heard that he was responsible for the failure. I've worked together with him before, and I have to say, it really was a pleasure. He's very accurate and diligent, but also polite and helpful.");
                next;
                mesn;
                mesq l("I really wonder what went wrong. I can't imagine Peetu messing up something so important.");
                if (is_between(4, 7, .@q))
                    setq1 NivalisQuest_BlueSage, .@q + 3;
                break;
            case 4:
                mesn;
                mesq l("Hm. Then please don't disturb me, I'm trying to concentrate.");
                close;
        }
    } while (@menu != 1);
    return;
}

OnInit:
    .sex=G_MALE;
    .distance=5;
    end;
}