// TMW2/LoF scripts.
// Authors:
//    TMW-LoF Team
//    Jesusalva
// Description:
//    Void NPC

018-2-1,22,29,0	script	Colonel DUSTMAN	NPC_CRUSADER,{
    .@cod=getq(LoFQuest_COD);
    .@hh=getq(LoFQuest_HH);
    mesn;
    mesq l("Hello adventurer. Are you interested in the Heroes Hold, or in the Call Of Dusty?");
    next;
    select
        l("Heroes Hold"),
        l("Call Of Dusty"),
        l("Neither, sorry");
    if (@menu == 3)
        close;
    else if (@menu == 2)
        goto L_COD;

    mes "";
    if (BaseLevel < 40) {
        mesn;
        mesq l("Well, my men went down and still haven't returned.");
        next;
        mesn;
        mesq l("I'm worried with them. Anyway, you need a special scroll to get to the Heroes Cave...");
        next;
        mesn;
        mesq l("Otherwise, well, I'm not sure what will happen. You'll probably be either thrown at the wolves or something. Duh.");
        next;
        mesn;
        mesq l("Take care, adventurer!");
        close;
    }
    mesn;
    mesq l("This whole region is called the Heroes Hold. It's designed for hard core, bragging-rights-hunters, high level, supreme players.");
    next;
    mesn;
    mesq l("This is the main hall. Below this stairs, you'll find the Heroes Hold Main Dungeon. It's a cave in a... uhm. Water.");
    mesq l("I thought it was meant to be lava, this being in the Land Of Fire and all, but seems like someone must bug Saulc to fix it.");
    next;
    mesn;
    mesq l("So, let's return to the bussiness at hand. My men went down and haven't returned. That was long ago, by the way.");
    mesq l("I can send you to at least five from the seven cave levels this dungeon have. Don't worry with the scroll.");
    if (.@hh == 0) {
        next;
        mesn;
        mesq l("Do you want to try to find them? Just search the first five floors: Novice, Intermediary, Advanced, Expert and Master.");
        mesq l("I don't have the scrolls for the Supreme and All-Might floors. So if you don't find them on the five and report back, that'll do.");
        next;
        mesc l("Accept quest?");
        if (askyesno() == ASK_YES) {
            mes "";
            mesn;
            mesq l("Wonderful! You must finish Novice, Intermediary, Advanced and Expert levels before I unlock Master level for you.");
            mesq l("I don't really understand how the dungeon works. I promise you a reward when you finish the task.");
            setq LoFQuest_HH, 1;
        }
    }
    close;

L_COD:
    mes "";
    if (BaseLevel >= 50 && .@cod < 1) {
        mesn;
        mesq l("Hey, do you know the ##BCall Of Dusty##b event?");
        next;
        if (#RARE_POINTS || countitem(TimeFlask)) {
            mesn;
            mesq l("Also, you seem like you are from around LoF. Why don't you take a free @@?", getitemlink(BottledDust));
            next;
            getitem BottledDust, 1;
        }
        setq LoFQuest_COD, 1;
    }
    mesn;
    mesq l("Just @@ ago, thiefs stole Pihro & Pyndragon weapons.", FuzzyTime(1542570030));
    next;
    if (BaseLevel >= 50 && .@cod < 2) {
        mesn;
        mesq l("Pyndragon said he'll do a @@ to however reduces them to dust. Interested?", getitemlink(Dustynator)); // BottledDust, Dustynator
        mesc l("Note: Dustynator is a high level weapon. You might not have enough level to use it yet.");
        next;
    } else if (BaseLevel < 50) {
        mesn;
        mesq l("It was a real problem, threating them to go out of business. I think they are trying to recover the lost weapons.");
        mesc l("Attain level 50 to try this quest.");
        close;
    } else {
        mesn;
        mesq l("Well, you already got the Dustynator, but you might want to collect more @@. They keep coming back, after all.", getitemlink(BottledDust));
        mesc l("Note: Killing enemies there with the Dustynator grants more dusty in a bottle.");
        next;
    }
    if (askyesno() == ASK_YES) {
        mes "";
        mesn;
        mesq l("Too bad, because that wasn't implemented yet!");
        mesc l("Report this to Jesusalva and he may finish this quest."), 1;
    }
    close;

OnInit:
    .sex=G_MALE;
    .distance=5;
    end;
}