// TMW2 Script
// Author:
//    Jesusalva
// Description:
//    Hunt mouboos, Summer Quest

012-1,68,74,0	script	Luffyx	NPC_RAIJIN,{
    .@q=getq(SQuest_Summer);
    mesn;
    if (season() == SUMMER) {
        mesq l("Yay it's summer! I love June 21st, and the summer vacations!");
        if (.@q < 1)
            goto L_SummerQuest;
    } else {
        mesq l("Aww it's not summer. I love June 21st, and the summer vacations!");
    }

L_Main:
    if (GHQUEST)
        GHQ_Assign(ForestMushroom, "Hurnscald", "275.000 GP, 60 "+getitemlink(StrangeCoin));
    close;

L_SummerQuest:
    next;
    mesn;
    // TODO: Sunglass
    mesq l("Hey, do you know what is good on summer? @@!", getitemlink(LuffyxSummerShorts));
    next;
    mesn;
    mesq l("What about you bring me 100 @@ and 30 @@?", getitemlink(RedApple), getitemlink(MoubooSteak));
    next;
    select
        l("Not now, thanks"),
        l("To be honest, I have that with me!");

    mes "";
    if (@menu == 1)
        goto L_Main;
    if (@menu == 2) {
        if (
            countitem(RedApple) < 100 ||
            countitem(MoubooSteak) < 30
            ) goto L_Lying;

        inventoryplace LuffyxSummerShorts, 1;
        delitem RedApple, 100;
        delitem MoubooSteak, 30;
        getitem LuffyxSummerShorts, 1;
        setq SQuest_Summer, 1;
        mesn;
        mesq l("Yay yay! Many thanks! Here, take the reward as promised!");
        next;
        mesn;
        mesq l("We can do this again on next summer!");
        goto L_Main;
    }

    close;

L_Lying:
    mesn;
    mesq l("Please don't lie to me...");
    goto L_Main;

OnInit:
    .@npcId = getnpcid(0, .name$);
    setunitdata(.@npcId, UDT_HEADTOP, CommunityShirt);
    setunitdata(.@npcId, UDT_HEADMIDDLE, JeansChaps);
    setunitdata(.@npcId, UDT_HEADBOTTOM, DeepBlackBoots);
    setunitdata(.@npcId, UDT_WEAPON, BugSlayer);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 13);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 7);

    .distance=4;
    .sex=G_MALE;
	end;

}