// TMW-2 Script
// Author:
//  Jesusalva
// Description:
//  This NPC is a work on progress. It measures all players equal.

008-0,47,63,0	script	Party Master	NPC_BRGUARD_SWORD,{
    mesn;
    if (getcharid(1) > 0) {
	    mesq l("You're in the \"@@\" party, very good!", getpartyname(getcharid(1)));
        next;
    } else {
        mesq l("I protect a dungeon for PARTIES. You're not on a party, get moving.");
        close;
    }

    mesn;
    mesq l("I protect a very dangerous dungeon, and it is so dangerous, that only parties can go in.");
    next;
    // TODO allow to go there if party leader is inside
    if (strcharinfo(0) != getpartyleader(getcharid(1))) goto L_NotYou;
    mesn;
    mesq l("There are five floors, and they're all very dangerous. But there are riches to be found.");
    next;
    mesn;
    mesq l("You also can't stay there forever! You will have 25 minutes to entirely clear it out and defeat the last boss.");
    next;
    // Get info about your party, and backup it
    getpartymember(getcharid(1));
	.@count = $@partymembercount;
	copyarray(.@name$[0], $@partymembername$[0], $@partymembercount);
	copyarray(.@aid[0], $@partymemberaid[0], $@partymembercount);
	copyarray(.@cid[0], $@partymembercid[0], $@partymembercount);
    .@count_online=0;

    if (.@count < 3 && !$@GM_OVERRIDE) goto L_TooSmall;
    mesn;
    mesc l("Are you and your party ready?", 1);
    if (askyesno() != ASK_YES)
        close;

    // Loop though party to see if you can start
	for (.@i = 0; .@i < .@count; ++.@i) {
        // Online?
		if (isloggedin(.@aid[.@i], .@cid[.@i])) {
            getmapxy(.@m$, .@x, .@y, 0, .@name$[.@i]);
            // Here?
            if (.@m$ == .map$)
    			.@count_online++;
        }
    }

    // How many are logged in and here?
    if (.@count_online < 3 && !$@GM_OVERRIDE) goto L_TooSmall;

    // TODO: Query if exp sharing is enabled
    // TODO: Instance for party

    // Warp everyone and add timers
    partytimer("008-0", 1000, "Party Master::OnStart", getcharid(1));
    warpparty("008-1", 176, 20, getcharid(1), "008-0", true);

    // TODO: Monsters
    monster("008-1", 90, 69, "Time Bonus", Scorpion, 1, "Party Master::OnAddTime");
    close;

L_NotYou:
    mesn;
    mesq l("If you bring me @@, your party leader, I can let you in.", getpartyleader(getcharid(1)));
    close;

L_TooSmall:
    mesn;
    mesq l("However, I need to see at least three volunteers here, to allow you in.");
    close;

OnStart:
    @pmloop=0;
OnLoop:
    if (getmapname() ~= "008-*") {
        @pmloop+=1;
        if (@pmloop < 1500) {
            addtimer(1000, "Party Master::OnLoop");
        } else {
            warp "008-0", 47, 64;
            dispbottom l("You ran out of time...");
        }
    } else {
        @pmloop=0;
    }
    end;

// TODO: We must use areatimer() and grant time bonus to everyone who killed it
OnAddTime:
    @pmloop=60;
    end;

OnInit:
    .sex = G_MALE;
    .distance = 5;
    end;
}