// TMW-2 Script.
// Author:
//    Povo
// Description:
//    Panoua - Camel Dye Quest (lvl 55)

004-3,32,24,0	script	Panoua	NPC_PLAYER,{
    mesn;
    mesq l("Life in the desert is simply the best.");
    next;
    goto L_Menu;

L_Menu:
    .@m$ =  (getq(HalinarzoQuest_Panoua) ? "Can you make me dye?" : "Do you sell anything?");
    mesn;   
    mesq l("Can I help you with anything traveller?");
    select
        l("Who are you?"),
        l("What is this place?"),
        l("I am lost, what should I do?"),
        l(.@m$),
        l("Nothing. I should get going.");

    mes "";
    switch (@menu)
    {
        case 1:
            mesn;
            mesq l("I am Panoua. Nice to meet you");
            next;
            goto L_Menu;
        case 2:
            mesn;
            mesq l("This is Pachua's Village, the only settlement located deep within the Tonori Canyon.");
            next;
            mesq l("Our village embraces the love for life in the desert and old nomadic traditions.");
            goto L_Menu;
        case 3:
            mesn;
            mesq l("The Tonori Canyon can certainly be overwhelming for less experienced travellers.");
            next;
            mesn;
            mesq l("If you get lost here I suggest, following your heart and channel your inner desert nomad.");
            next;
            mesn;
            mesq l("Or maybe you could retrace your steps or something.");
            goto L_Menu;
        case 4:
            mesn;
            mesq l("I have mastered the art of crafting traditional desert dyes.");
            mesq l("Ya know, for clothes and stuff."); 
            next;
            mesn;
            mesq l("The only problem is I cannot sell any to you because I am all out of ingredients.");
            next;
            if (BaseLevel < 55) { 
                mesq l("If you were stronger, I would propose a trade. However, I cannot burden a low level adventurer with a task so dangerous.");
                goto L_Menu;
            }
            mesq l("I have an idea!");
            next;
            mesn;
            mesq l("If you bring me the ingredients, I will make a dye for you... for a small fee of course");
            next;
            goto L_Offer;
        case 5:
            goto L_Quit;
    }

L_Offer:
    .@q = getq(HalinarzoQuest_Panoua);
    mesn;
    mesq l("Here is what I will need for one %s", getitemlink(CamelDye));
    mesq l("");
    mesq l("%s/%s GP",fnum(Zeny), fnum(5000));
    mesq l("%d/%d %s",countitem(BottleOfTonoriWater), 1, getitemlink(BottleOfTonoriWater));
    mesq l("%d/%d %s",countitem(AlizarinHerb), 50, getitemlink(AlizarinHerb));
    mesq l("%d/%d %s",countitem(IronPowder), 30, getitemlink(IronPowder));
    mesq l("%d/%d %s",countitem(SnakeTongue), 2, getitemlink(SnakeTongue));
    mesq l("%d/%d %s",countitem(YellowDye), 2, getitemlink(YellowDye)); 
    mesn;
    mesq l("So what do you think? Want one?");
    compareandsetq HalinarzoQuest_Panoua, 0, 1;
    goto L_Dye;

L_Dye:
    if (askyesno() == ASK_NO)
        goto L_Quit;
        
    mes "";
    if (@menu == 2)
        goto L_Quit;
    
    if (countitem(BottleOfTonoriWater) >= 1 &&
          countitem(AlizarinHerb) >= 50 &&
          countitem(IronPowder) >= 30 &&
          countitem(SnakeTongue) >= 2 &&
          countitem(YellowDye) >= 2 &&
          Zeny >= 5000) {
        inventoryplace CamelDye, 1, EmptyBottle, 1;
        delitem BottleOfTonoriWater, 1;
        delitem AlizarinHerb, 50;
        delitem IronPowder, 30;
        delitem SnakeTongue, 2;
        delitem YellowDye, 2;
        Zeny=Zeny-5000;
        getitem CamelDye, 1;
        getitem EmptyBottle, 1;
        if (getq(HalinarzoQuest_Panoua) < 2) {
            setq HalinarzoQuest_Panoua, 2;
            getexp 20000, 0;
        }   
        mesn;
        mesq l("Thanks! Here's your dye. Do you want more?");
        next;
        goto L_Dye;
    } else {
        mesn;
        mesq l("Sorry, you seem to be missing some things.");
        next;
        goto L_Menu;
    }
    close;

L_Quit:
    closedialog;
    goodbye;
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, NPCEyes);
    setunitdata(.@npcId, UDT_HEADMIDDLE, DesertShirt); 
    setunitdata(.@npcId, UDT_HEADBOTTOM, CottonTrousers);
    setunitdata(.@npcId, UDT_WEAPON, DeepBlackBoots); // Boots
    setunitdata(.@npcId, UDT_RACE, MedHu);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 19);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 1);
    
    .sex = G_OTHER;
    .distance = 5;
    end;
}