// TMW2 scripts.
// Author:
//    Jesusalva
// Description:
//    Tulimshar Inn Recepcionist

003-9,42,123,0	script	Gambler Master	NPC_LOF_NOBLEMAN,{
    mesn;
    mesq l("Hello! Welcome to the Inn! I am an Alliance officer, and I oversee gambling all over the world!");
    next;
    mesn;
    mesq l("So how can I help you?");
    do
    {
        next;
        select
            l("I want to turn over my Casino Coins."),
            l("How does Gambling works?"),
            l("How can I obtain casino coins?"),
            l("Nothing, thanks.");
        mes "";
        switch (@menu) {
            case 1:
                goto L_Trade;
            case 2:
                mesn;
                mesq l("You find a slot machine or another gambler, and make a bet!");
                next;
                mesn;
                mesq l("If you're right, you'll gain more Casino Coins! And even other nice things!");
                next;
                mesn;
                mesq l("But if you're wrong, you'll have to pay up! There's no refunds. This is gambling, if you lose you lose!");
                next;
                mesn;
                mesq l("If you're afraid of losing everything, then DEFINITELY do not gamble. %%2");
                break;
            case 3:
                mesn;
                mesq l("I dunno. I don't think they're sold anywhere.");
                next;
                mesn;
                mesq l("I know a few bandits stole a few, and Lava Slimes love to eat Casino Coins.");
                next;
                mesn;
                mesq l("I've even heard of people whom dug Casino Coins out of the ground, but as I said, I don't know. But you'll certainly come across a few o your adventures!");
                break;
        }
    } while (@menu != 4);
    close;

L_Trade:
    openshop;
    closedialog;
    close;

OnInit:
    .sex = G_MALE;
    .distance = 5;
	tradertype(NST_CUSTOM);

    sellitem MercBoxA, 940;
    sellitem JeansShorts, 820;
	sellitem ElixirOfLife, 150;
    sellitem PoisonArrow, 30;
    sellitem StrangeCoin, 5;
    end;

OnCountFunds:
	setcurrency(countitem(CasinoCoins));
	end;

OnPayFunds:
	if( countitem(CasinoCoins) < @price )
		end;
	delitem CasinoCoins,@price;
	purchaseok();
	end;
}