// TMW2 Script
// Description:
//    Main start NPC

000-0,23,19,0	script	Lost Travelers	NPC_SAILORS,6,6,{

OnTouch:
    //if (TUT_VAR)
    //    end;

    //checkclientversion;
    .@lang = requestlang();
    if (.@lang >= 0 && .@lang <= MAX_LANG) Lang = .@lang;

    showavatar NPC_SAILORS;

    // Standard Procedures
    if (!getvaultid()) {
        mesc l(".:: ERROR ::."), 1;
        mesc l("This world is exclusive for Mirror Lake Users.");
        next;
        kick(getcharid(3), 5);
        end;
    }
    // TODO: Check if you have a homeworld set
    if (get_nibble(##00_INFO, 4) <= 1) {
        mesc l(".:: ERROR ::."), 1;
        mesc l("You must set a home world first. Then you will be able to use the Crossroads.");
        next;
        kick(getcharid(3), 5);
        end;
    }


    // Set your language (WIP?)
    asklanguage(LANG_ON_SEA);
    clear;


    mesc l("Welcome to..."), 3;
    mes "";
    mesc b(l("        The Crossroads       ")), 1;
    mesc l("- The world between mana worlds -"), 1;
    mes "";
    mesc l("The only place where your home world is meaningless."), 2;
    mes "";
    mesc l("This game follows the same gameplay rules as %s. Equipment real effects may differ from their description because this.", b(l("Moubootaur Legends")));
    next;
    clear;
    GameRules(8 | 4);
    clear;
    closeclientdialog;

    // No naked players
    getitem CreasedShirt, 1;
    getitem CreasedShorts, 1;
    equip(CreasedShirt);
    equip(CreasedShorts);

    // Basic setup
    adddefaultskills;
    percentheal 100,100;
	TUT_VAR=gettimetick(2);
    #TUTORIAL_DONE=true;
    #REG_DATE=gettimetick(2);

    // Final warp
    warp "033-1", 122, 192;
    savepoint "033-1", 122, 192;

    // Import exp, gp and items if not done already
    clientupdater();
    close;

OnInit:
    .sex = G_MALE;
    end;
}